Mirley - Elektronika i Programowanie

Witam!!!
Chciałbym się Pana spytać jak przerobić ten program aby można było całą pracę układu DS1267 pokazać na wyświetlaczu LCD?

Witam!!!
Spróbowałem sam przerobić ten program i wyszło mi coś takiego:

$regfile = "m16def.dat"
$crystal = 8000000
Config Portb = &B11111010 : Portb = &B11100101
Config Portd = Output ; Portd = &B11111111
Config Lcdpin = Pin , Db4 = Portd.0 , Db5 = Portd.1 , Db6 = Portd.2 , Db7 = Portd.3 , Rs = Portd.4 , E = Portd.5
Config Lcd = 16 * 2
Deflcdchar 0 , 12 , 4 , 4 , 6 , 12 , 4 , 4 , 14             'ł
Deflcdchar 1 , 2 , 4 , 32 , 15 , 16 , 14 , 1 , 30           'ś
Deflcdchar 2 , 2 , 4 , 32 , 15 , 16 , 16 , 16 , 15          'ć
Rst Alias Portb.3
Dq Alias Portb.1
Clk Alias Portb.4
Splus Alias Pinb.0
Sminus Alias Pinb.2
$hwstack = 20
$swstack = 10
$framesize = 40
Dim N As Byte , Dane As Word
Dim Licz_sw(2) As Byte
Dim Glos As Byte
Dim Autosave As Byte
N = 15
Readeeprom Glos , 1
Glos = Glos / 2
Glos = Glos * 2
Clk = 0
Dane = 256 * Glos
Dane = Dane + Glos
Rst = 1
Do
If Rst = 1 Then
If Clk = 1 Then
If N <> 255 Then
Dq = Dane.n
Decr N
Else
Rst = 0
Dq = 0
N = 15
End If
End If
Toggle Clk
Else
Waitms 5
If Splus = 0 Then
Incr Licz_sw(1)
If Licz_sw(1) = 10 Then
Licz_sw(1) = 0
If Glos <= 253 Then
Autosave = 250
Glos = Glos + 2
Clk = 0
Dane = 256 * Glos
Dane = Dane + Glos
Rst = 1
Waitms 50
End If
End If
Else
Licz_sw(1) = 0
End If
If Sminus = 0 Then
Incr Licz_sw(2)
If Licz_sw(2) = 10 Then
Licz_sw(2) = 0
If Glos >= 2 Then
Autosave = 250
Glos = Glos - 2
Clk = 0
Dane = 256 * Glos
Dane = Dane + Glos
Rst = 1
Waitms 50
End If
End If
Else
Licz_sw(2) = 0
End If
If Autosave > 0 Then
Decr Autosave
If Autosave = 0 Then
Writeeeprom Glos , 1
End If
End If
Cls
Lcd "G" ; Chr(0) ; "o" ; Chr(1) ; "no" ; Chr(1) ; Chr(2) ; ":"
Lowerline
Lcd "+" ; Glos ; "dB"
End If
Loop
End

Czy dobrze to wszystko napisałem?
Jeżeli nie to proszę poprawić tak aby było dobrze.
Fragment programu, który sam to:

Cls
Lcd "G" ; Chr(0) ; "o" ; Chr(1) ; "no" ; Chr(1) ; Chr(2) ; ":"
Lowerline
Lcd "+" ; Glos ; "dB"
End If
Loop
End  

Zrób wcięcia w programie bo nie ma szans tego zanalizować.....

Witam!
Jestem początkującym programistą i nie wiem jak to zrobić.Byłbym bardzo wdzięczny jak pan mógłby mi ten program przerobić.

To w takim razie napisz co masz na myśli "pokazac całą pracę na LCD"? pokazać położenia suwaków?, czy głośnośc w 100% bo tak wnioskuję z wcześniejszych postów?

chciałbym aby na wyświetlaczu była taka podziałka -[-----------]+.Czyli jak pan się domyśla jest to podziałka głośności.Jak będzie się pogłaszało muzykę to kursor będzie przechodził powoli w prawą stronę a jak przyciszało to w lewą.A w drugiej linijce wyświetlacza chciałbym aby był taki napis:
Głośność:(w tym miejscu cyfry od 0 do 30 w zależności od pogłoszenia)dB.
Myślę, że teraz chyba będzie pan wiedział o co mi chodzi?

Górną linijkę rozumiem ale niewiem skąd mamwytrzasnąć ci wzmocnienie w decybelach. Chodzi ci zrobienie wskaźnika tłumienia potencjometru głośności? tak wogóle to chodziło ci chyba o skalę od -ileś do 0 bo dodatnia wartość oznacza wzmocnienie które trzeba znać aby to policzyć (taki szkolny wzór z logarytmem: 20*log(Uout/Uin))? Chyba że poprostu ma to pokazywać położenie suwaka za pomocą liczby tak jak zrobiłeś to w twojej wersji programu?

dokładnie tak ja w mojej wersji programu

Mirley: reszta postów usunięta, nie wolno pisać swoich postów jeden pod drugim, albo się zaloguj uzyskując możliwość edycji albo dokładnie przemyśl co chcesz pisać bo nie mam czasu na scalanie pojedynczych wpisów

Zrobi się ale trzeba mieć trochę czasu

--------------
Sprawdź tak:

$regfile = "m16def.dat"
$crystal = 8000000
 
$hwstack = 20
$swstack = 10
$framesize = 40
 
Config Portb = &B11111010 : Portb = &B11100101
Config Portd = &B11111111 ; Portd = &B11111111
Config Portc = &B00000000 ; Portd = &B11111111
 
Config Lcdpin = Pin , Db4 = Portd.0 , Db5 = Portd.1 , Db6 = Portd.2 , Db7 = Portd.3 , Rs = Portd.4 , E = Portd.5
Config Lcd = 16 * 2
Deflcdchar 0 , 12 , 4 , 4 , 6 , 12 , 4 , 4 , 14             'ł
Deflcdchar 1 , 2 , 4 , 32 , 15 , 16 , 14 , 1 , 30           'ś
Deflcdchar 2 , 2 , 4 , 32 , 15 , 16 , 16 , 16 , 15          'ć
Cls
 
Rst Alias Portb.3
Dq Alias Portb.1
Clk Alias Portb.4
Splus Alias Pinb.0
Sminus Alias Pinb.2
 
 
Dim N As Byte , Dane As Word
Dim Licz_sw(2) As Byte
Dim Glos As Byte
Dim Autosave As Byte
dim x as byte
N = 15
 
Readeeprom Glos , 1
Glos = Glos / 2
Glos = Glos * 2
Clk = 0
Dane = 256 * Glos
Dane = Dane + Glos
Rst = 1
 
Do
  If Rst = 1 Then                                           'wysylanie
    If Clk = 1 Then
      If N <> 255 Then
        Dq = Dane.n
        Decr N
      Else
        Rst = 0
        Dq = 0
        N = 15
      End If
    End If
    Toggle Clk
  Else
    Waitms 5
    '******************************** przyciski
    If Splus = 0 Then
      Incr Licz_sw(1)
      If Licz_sw(1) = 10 Then
        Licz_sw(1) = 0
        If Glos <= 253 Then
          Autosave = 250
          Glos = Glos + 2
          Clk = 0
          Dane = 256 * Glos
          Dane = Dane + Glos
          Rst = 1
          gosub LCD
          Waitms 50
        End If
      End If
    Else
      Licz_sw(1) = 0
    End If
 
    If Sminus = 0 Then
      Incr Licz_sw(2)
      If Licz_sw(2) = 10 Then
        Licz_sw(2) = 0
        If Glos >= 2 Then
          Autosave = 250
          Glos = Glos - 2
          Clk = 0
          Dane = 256 * Glos
          Dane = Dane + Glos
          Rst = 1
          gosub LCD
          Waitms 50
        End If
      End If
    Else
      Licz_sw(2) = 0
    End If
    '******************************** przyciski koniec
 
    If Autosave > 0 Then
      Decr Autosave
      If Autosave = 0 Then
        Writeeeprom Glos , 1
      End If
    End If
 
  End If
Loop
End
 
 
LCD:
cls
lcd "-[------------]+"
x = glos/23
x=x+3
locate 1,x
lcd "|"
lowerline
lcd "glos: "; glos
return

sprawdź to teraz bo napisałem na sucho bez kompilacji i mogą być błędy. Program to prawie w całości projekt pot. cyfrowego

Czyli mam teraz zaprogramować procka?

Wkleić do bascoma skompilować i wgrać czy będzie działało..... nie mam czasu aby to sprawdzać dokładnie. Mam nadzieje że dobre piny do lcd wpisałeś w programie

Skompilowało się dobrze ale wgram jutro ponieważ zamówiłem dopiero procesor i jutro ma mi dojść.
W programie jest kwarc 8MHz czy mogę zmienić na 16MHz bo tylko taki mam?
A z tymi pinami do lcd to oco chodzi?

Możesz dać 16MHz ale na początku programu musisz to zdefiniować, w linijce crystal. Lcd musisz zdefiniować do jakich pinów podłączyłeś:

Config Lcdpin = Pin , Db4 = Portd.0 , Db5 = Portd.1 , Db6 = Portd.2 , Db7 = Portd.3 , Rs = Portd.4 , E = Portd.5

witam!
czy ATMEGA16 różni się czymś od ATMEGA16A?

Teoretycznie nie różni się niczym, te z literą A to nowe opracowania ATMELA będące połączeniem M16 i M16L. Z tego co wiem to nie będzie już wersji LOW power bo załatwia to jeden mikrokontroler z literka A.

czyli z zaprogramowaniem tej atmegi16a jest takie samo jak zaprogramowanieatmegi16?

nie

a czemu nie?

Tak, tak można przepraszam byłem zmęczony i zapomniałem, aha a moze kolega zdradzic gdzie dorwał już takie atmegi, na allegro.pl nie ma

wejdź na TME.EU tam znajdziesz za 13,90pln netto

Mireczku, mam pytanie bo nie mogę się doczytać:

jak odczytać wartość aktualnego położenia suwaków?
jest to zapisane w tym miejscu?

Readeeprom Glos , 1

Nie, jest to standardowa funkcja odczytu z eeprom.

Readeeprom Zmienna , Adres

1 jest adresem w pamięci eeprom z którego czytam położenie obu suwaków. Zmienna głos przechowuje położenie suwaków. Oba potencjometry mają takie samo położenie

a jeszcze jedno pytanie.
da się wprowadzić ów potencjometr od razu w tryb mute?
jeśli tak to jak to zrobić?

Nie ma czegoś takiego jak mute potencjometru... jak sobie to wyobrażasz, potencjometr cyfrowy z punktu widzenia wzmacniacza jest taki sam jak zwykły potencjometr. Można na początku programu ustawić suwak w skrajnym położeniu, aby wejście wzmacniacza było zwarte do masy, wtedy uzyskasz wyciszenie

to mute to umowne. tylko jak ustawić ten potencjometr na zero?

Popatrz do karty katalogowej.... potencjometr ma rejestr przesuwny 16 bitowy do zapisu położenia suwaków. Jak wpiszesz w dwa bajty 0 to suwak ustawi sie na minimum. ja robię z dwóch bajtów wartość Word (przykład pierwszy na górze):

Dane = 256 * Pot_A            'tworzenie 16-bitowej zmiennej z wartoscią potencjometrów
Dane = Dane + Pot_B

Wystarczy jak w Pot_A i Pot_B będzie wpisane 0 i suwak ustawiony

W programie niżej masz tylko jedna zmienną Glos i wpisuje się ona w dwa suwaki, więc wystarczy Glos = 0 i uruchomic procedurę wysyłania poprzez RST=1

Jaki to język ? Panie MF

Bascom AVR (Basic)

Witam, kiedyś w Bascomie programowałem... ale to były lata świetlne temu. Teraz mam "problem" i proszę o pomoc.
Muszę zrobić timer. Przeważnie to są przyciski góra - dół, wybieranie sekwencyjne... nikt tego nie lubi.
W kuchence mikrofalowej mam zegar - naciskam przycisk ustawiam godziny kręcąc pokrętłem w lewo lub w prawo.
Naciskam ponownie przycisk ustawiam minuty (kręcąc pokrętłem w lewo lub w prawo). Naciskam przycisk zatwierdzam ustawienia. Rozwiązanie bardzo fajne. Może ktoś by pomógł?
Pozdrawiam

Witam! Masz na tej stronie gotowe rozwiązanie. Poczytaj o enkoderze.

Witam

mam pytanie, może mi pomożesz.
Potrzebuję wiedzy jak ma wyglądać kod w Bascomie kiedy podłączę dwa układy ds1267.
opracowałeś kod pod jeden i ok działa a jak mam uruchomić drugi?

jest taka możliwość?

Byłbym wdzięczny za poradę , sugestię... może nawet za gotowy kod.

pozdrawiam

Można podłączyć dowolną ilośc potencjometrów w szeregu. Kłania sie karta katalogowa na stronie 4 i 5 "Cascade Operation". W kodzie źródłowym trzeba: Zmienić zmienną Dane na typ Long (4 bajty), a zmienna N powinna miec domyślnie N = 31 a nie N = 15. W zmiennej Dane trzeba zapisac 4 bajty określające położenia suwaków