Mirley - Elektronika i Programowanie

'****************************
           'Konfiguracja
'****************************
$regfile = "attiny2313.dat"
$crystal = 12000000
 
Config Portb = &B11111111 : Portb = &B11111111
Config Portd = &B11100111 : Portd = &B11111111
 
Config 1wire = Pind.5
 
Config Timer0 = Timer , Prescale = 64
Enable Timer0 : On Timer0 Przerwanie0
 
 
Enable Interrupts
'****************************
      'Zmienne
'****************************
Dim Lsb As Byte
Dim Msb As Byte
Dim Co4ms As Byte , Co100ms As Byte , Co1s As Byte
Dim Wysw As Word , Wysw1 As Byte , Wysw10 As Byte , Wysw100 As Byte
Dim Wysw_pomoc As Word
Dim Tempa As Word
Dim Mux As Byte
 
Dim Zezw_wysw As Bit
Dim Pomiar_odczyt As Bit
Dim Minus As Bit
Dim Ur As Bit
Dim L_sw As Byte
Dim P As Bit
Dim Ww As Byte
Dim Flaga_s As Bit
Dim Th As Word , Tl As Word , Tt As Word
 
Th = 290                                                    'wstępna temperatura włączenia *10, 290 oznacza 29 stopni 500 to 50 stopni
Tl = Th - 20                                                ' temperatura wyłaczenia, 20 to histereza - można zmienić na własne potrzeby
'****************************
      'Wartosci Poczatkowe
'****************************
Reset Pomiar_odczyt
Reset Ur
Wysw1 = 191
Wysw10 = 191
Wysw100 = 191
'****************************
      'Petla glowna
'****************************
Do
 
Tl = Th - 20
If Zezw_wysw = 1 Then
  Reset Zezw_wysw
 
  If Ur = 1 Then Gosub Przelicz
  Gosub Wyswietl
  End If
 
  If Flaga_s = 1 Then
  Reset Flaga_s
 
  If Tempa > Th Then
    Portd.6 = 1
  Else
    If Tempa < Tl Then Portd.6 = 0
  End If
 
End If
 
If P = 1 Then
  Wysw = Th
Else
  Wysw = Tempa
End If
 
Loop
End
'****************************
      'Przerwanie timer0
'****************************
Przerwanie0:
Timer0 = 5
Incr Co4ms
 If Co4ms = 3 Then
   Co4ms = 0
   '***************************************  co 4ms
   Set Zezw_wysw
   Incr Co100ms
   If Co100ms = 25 Then
     Co100ms = 0
     '*************************************** co 100 ms
     'obsluga przyciskow
If Pind.4 = 0 Then
      Incr L_sw
         If L_sw = 3 Then
         L_sw = 0
         Set P
         Th = Th + 10
         Ww = 1
            If Th = 500 Then                                ' górny zakres ustawianej temperatury
            Th = 490
            End If
         End If
End If
 
If Pind.3 = 0 Then
Incr L_sw
     If L_sw = 3 Then
      L_sw = 0
      Set P
      Th = Th - 10
      Ww = 1
            If Th = 200 Then                                ' dolny zakres ustawianej temperatury
            Th = 210
            End If
       End If
 
End If
 
Incr Ww
If Ww = 50 Then                                             'czas wyświetlania ustawionej temperatury (50 x 10ms = 5s)
Ww = 0
Reset P
End If
 
     Incr Co1s
     If Co1s = 7 Then
       Co1s = 0
       '*************************************** co 1s
       Set Flaga_s
       Pomiar_odczyt = Not Pomiar_odczyt
 
       Disable Interrupts
       1wreset
 
       If Pomiar_odczyt = 1 Then
        1wwrite &HCC
        1wwrite &H44
       Else
        If Err = 0 Then
 
          1wwrite &HCC
          1wwrite &HBE
          Lsb = 1wread():
          Msb = 1wread():
 
          Minus = Msb.7
 
          Tempa = Msb * 256
          Tempa = Tempa + Lsb
 
 
          If Minus = 1 Then
            Tempa = Not Tempa
            Tempa = Tempa + 1
          End If
 
          Tempa = Tempa * 10
          Tempa = Tempa / 16
 
          If Ur = 0 Then Ur = 1
 
        Else
          Tempa = 10000
        End If
       End If
 
       Enable Interrupts
       '***************************************
     End If
     '***************************************
   End If
   '***************************************
 End If
 
Return
'****************************
      'Inne Etykiety
'****************************
Przelicz:
 If Wysw < 1000 Then
   Wysw_pomoc = Wysw Mod 10
   Wysw1 = Wysw_pomoc
   Wysw = Wysw / 10
   Wysw_pomoc = Wysw Mod 10
   Wysw10 = Wysw_pomoc
   Wysw = Wysw / 10
   Wysw_pomoc = Wysw Mod 10
   Wysw100 = Wysw_pomoc
 
   If Wysw100 = 0 Then Wysw100 = 10                         'wygaszenie zera wiodącego
 
   Wysw1 = Lookup(wysw1 , Tabela)
   Wysw10 = Lookup(wysw10 , Tabela2)
   Wysw100 = Lookup(wysw100 , Tabela)
 
 Else
   Wysw1 = 175                                              'r
   Wysw10 = 175                                             'r
   Wysw100 = 134                                            'E
 End If
 
Return
 
 
Wyswietl:
 
  Incr Mux
  If Mux = 3 Then Mux = 0
 
  Select Case Mux
    Case 0:
     Set Portd.0
      Portb = Wysw100
     Reset Portd.2
 
    Case 1:
     Set Portd.2
      Portb = Wysw10
     Reset Portd.1
 
    Case 2:
     Set Portd.1
     Portb = Wysw1
     Reset Portd.0
  End Select
 
Return
 
'****************************
 
'****************************
 
 
'*******************************************************************************
                           'Tabele do wyswietlania na wyswietlaczu
'*******************************************************************************
Tabela:
    Data 192 , 249 , 164 , 176 , 153 , 146 , 130 , 248 , 128 , 144 , 255
'znak:    0     1     2     3     4     5     6     7     8     9     pusty
 
Tabela2:
    Data 64 , 121 , 36 , 48 , 25 , 18 , 2 , 120 , 0 , 16 , 255
'znak:    0.    1.  2.    3.   4.   5.  6.   7.   8.  9.    pusty
'************************************************************************************************