Urządzenie to jak sama nazwa wskazuje jest sterownikiem do instalacji centralnego ogrzewania. Układ sprawdza się w bardzo prostych instalacjach posiadających jedną wspólną pompkę do grzejników i do wymiennika C.W.U. W wersji podstawowej nie jest oprogramowany wentylator nadmuchowy, gdyż nie było go w instalacji w której opisywany sterownik miał działać. Dodatkowe wyjście z triakiem pozwoli łatwo zmodyfikować program i dodać obsługę wentylatora. Sterownik posiada dwa tryby pracy, letni w którym głównie nastawia się na grzanie wody i pompa pracuje gdy temperatura na piecu jest większa niż w wymienniku, oraz tryb zimowy gdzie pompa pracuje zawsze gdy temperatura na piecu jest większa od minimalnej. Dodatkową funkcją sterownika jest pomiar temperatury na piecu, w bojlerze, w domu i na zbiorniku wyrównawczym. Konfiguracja w menu pozwala ustawić temperaturę minimalną i alarmową oraz zmieniać tryb pracy.
Schemat ideowy układu znajduje się na rysunku poniżej:
Sercem układu jest mikrokontroler U1 (ATMega8) wraz z rezonatorem kwarcowym X1(16MHz) i kondensatorami C1 (22pF) i C2 (22pF). Kondensatory C3 (220uF) i C4 (100nF) filtrują napięcie zasilania, które powinno zostać podane na złącze Zas (ARK2) z drugiej płytki sterownika. Potencjometr P1 (10k) umożliwia regulację kontrastu wyświetlacza W1 (LCD 2x16). Za pomocą tranzystora T1 (BC556) i rezystora R2 (3,3k) możliwe jest włączenie podświetlania wyświetlacza w sposób programowy. Rezystor R1 (47R) ogranicza prąd struktur LED podświetlających wyświetlacz. Buzzer z generatorem BUZ1 (5V) pełni funkcję sygnalizatora alarmu. Alarm uruchamiany jest za pośrednictwem tranzystora T2 (BC556) oraz rezystorów R3 (3,3k) i R4 (3,3k) gdy temperatura przekroczy ustawiony próg. Złącze 1W_TR (ARK3) służy do podłączenia magistrali 1-Wire z czujnikami DS18B20 (4 sztuki) oraz zapewnia połączenie sterownika z płytka wykonawczą. Układ U2 jest w praktyce podstawką pod czujnik DS18B20, która przydaje się w momencie rejestracji czujników. Zworka 1W_ENA (goldpin) umożliwia odłączenie całej magistrali od płytki na czas rejestracji czujników. Rezystor R8 (4,7k) jest konieczny do poprawnej pracy układów DS18B20. Zworki DSR1...DSR3 (goldpin) poprzez różne kombinacje pozwalają na wybranie który czujnik ma być w danej chwili zarejestrowany. Przyciski S1..S3 (uSwitch) stanowią klawiaturę urządzenia, natomiast diody D1..D3 (LED) wraz z rezystorami ograniczającymi prąd R5...R7 (470R) stanowią kontrolki pracy pompy, wentylatora oraz alarmu. Złącze Prog (goldpin) służy do zaprogramowania procesora, podobnie jak pin Res, który dodatkowo umożliwia reset procesora podczas rejestracji czujników.
Schemat ideowy układu wykonawczego znajduje się na rysunku poniżej:
W skład modułu wykonawczego wchodzi stabilizator napięcia U1 (7805) wraz z kondensatorami C1 (220uF) i C2 (47uF). Do złącza Zas (ARK) należy podłączyc napięcie o wartości w granicach 7-15V, w pierwowzorze miała to być ładowarka od telefonu. Złącze VCC (ARK) umożliwia zasilanie sterownika. W roli elementów wykonawczych pracują triaki TR1 (BT138-600E) oraz TR2 (BT138-600E), rezystory R2 (180R), R3 (180R), R5 (180R) i R6 (180R) ograniczają prąd bramek triaków. W rolli zabezpieczenia przeciwprzepięciowego zastosowano warystory WR1 (JVR-7N431) i WR2 (JVR-7N431), chociaż nie są one wymagane. Przed zwarciem zabezpiecza bezpiecznik F1 (2A). Złącze 230V umożliwia podłączenie zasilania sieciowego do płytki. Wyjściami napięciowymi dla pompy i wentylatora są złącza TRO1 (ARK) i TRO2 (ARK). Oddzielenie wysokonapięciowych obwodów sieciowych od niskonapięciowego sterownika zapewniają optotriaki OPT1 (MOC3041) i OPT2 (MOC3041). Prąd ich struktur LED ograniczają rezystory R1 (330R) i R2 (330R), a szeregowo włączone diody LED sygnalizują stan triaków. Do złącza TRI (ARK) podłączamy wyjścia sterownika.
Układ z powodzeniem można zbudować w oparciu o płytkę drukowaną dostępną tutaj. Rysunek w odbiciu lustrzanym dostępny jest tutaj. Pomocą w konstrukcji może okazać się schemat montażowy dostępny tutaj.
Układ wykonawczy można zbudować w oparciu o płytkę drukowaną dostępną tutaj. Rysunek w odbiciu lustrzanym dostępny jest tutaj
Pomocą w konstrukcji może okazać się schemat montażowy dostępny tutaj.
1x Złącze śrubowe ARK2(podwójne)
1x Złącze śrubowe ARK3(potrójne)
4x Listwa Goldpin 1x2 (1W_ENA)
1x Listwa Goldpin 1x3 (DS18B20)
1x Listwa Goldpin 1x4 (Prog)
3x uSwitch
3x 3,3k
1x 47R
3x 470R
1x 4,7k
1x Potencjometr Montażowy 10k
2x 22pF
1x 100nF
1x 220uF Elektrolit
1x Rezonator Kwarcowy 16MHz
3x Dioda LED
2x BC556
1x Mikrokontroler ATMEGA8 + Podstawka
1x Buzzer z Generatorem 5V
1x 16x2
1x Bezpiecznik 2A
6x Złącze śrubowe ARK2(podwójne)
4x 180R
2x 330R
2x Warystor JVR-7N431
1x 47uF Elektrolit
1x 220uF Elektrolit
2x Dioda LED
1x Stabilizator 7805
2x BT138-600E
2x MOC3041
Kod Źródłowy do sterownika został napisany w BASCOM AVR firmy MCS Electronics (http://www.mcselec.com/). Program przedstawiony jest poniżej:
'************* Konfiguracja uC *****************
'***********************************************
$regfile = "m8def.dat"
$crystal = 16000000
'Config Porta = &B00111111 : Porta = &B11111111
Config Portb = &B11111000 : Portb = &B11111111
Config Portc = &B11111111 : Portc = &B11111111
Config Portd = &B00011111 : Portd = &B11111111
Config Lcdpin = Pin , Db4 = Portc.3 , Db5 = Portc.2 , Db6 = Portc.1 , Db7 = Portc.0 , E = Portc.4 , Rs = Portc.5 'mirley UPT M16
Config Lcd = 16 * 2
Cls
Cursor Off Noblink
Config 1wire = Pind.2
Sw_port Alias Pinb 'nazwa portu
Pompa Alias Portd.3
Went Alias Portd.4
Buzz Alias Portd.1
Light Alias Portd.0
Ds1r Alias Pind.7
Ds2r Alias Pind.6
Ds3r Alias Pind.5
Led_a Alias Portb.5
Led_p Alias Portb.3
Led_w Alias Portb.4
Config Timer0 = Timer , Prescale = 256
Enable Timer0 : On Timer0 Prztimer0
Enable Interrupts
'********** Konfiguracja uC Koniec ************
'****************** Zmienne *******************
'***********************************************
Dim Stan_sw As Byte , Sw As Byte , Licznik_sw As Byte 'sw
Dim Wyswietlanie As Byte , Poz_wysw As Byte , Wyswietlono As Bit 'Lcd
Dim Mig As Bit , Poz_ust As Byte
Dim Autosave As Byte , Autopowrot As Byte , Autolight As Byte
Dim Ds1(8) As Byte , Ds2(8) As Byte , Ds3(8) As Byte , Ds4(8) As Byte , Ds(8) As Byte , Ds_adr As Byte , Ds_ok As Bit 'DS18B20
Dim Ktory_ds As Byte , Lsb As Byte , Msb As Byte , Minusy As Byte
Dim T(4) As Word
Dim T_min As Word , T_alarm As Word
Dim Dzielnik(2) As Byte 'dzielniki timera
Dim Flaga_4ms As Bit , Flaga_500ms As Bit , Flaga_1s As Bit 'flagi przerwa?
Dim Hbyte(2) As Byte , Hword(3) As Word , N As Byte , Hbit As Bit , M As Byte
Dim Buzz_en As Bit
Dim Tryb_letni As Bit '0- tryb zimowy, 1- tryb letni
'************* Zmienne Koniec ****************
'************ Warunki Poczatkowe ***************
'***********************************************
Light = 0
Lcd " Sterownik C.O."
Lowerline
Lcd " Wersja 0.96"
Wait 1
If Ds1r = 1 And Ds2r = 0 And Ds3r = 0 Then
Ds_adr = 30
Gosub Ds_reg
Cls
Lcd "Ds Piec"
End If
If Ds1r = 0 And Ds2r = 1 And Ds3r = 0 Then
Ds_adr = 40
Gosub Ds_reg
Cls
Lcd "Ds Bojler"
End If
If Ds1r = 1 And Ds2r = 1 And Ds3r = 0 Then
Ds_adr = 50
Gosub Ds_reg
Cls
Lcd "Ds Zbiornik"
End If
If Ds1r = 0 And Ds2r = 0 And Ds3r = 1 Then
Ds_adr = 60
Gosub Ds_reg
Cls
Lcd "Ds Kuchnia"
End If
For N = 1 To 8
Hbyte(1) = 30 + N
Readeeprom Ds1(n) , Hbyte(1)
Hbyte(1) = 40 + N
Readeeprom Ds2(n) , Hbyte(1)
Hbyte(1) = 50 + N
Readeeprom Ds3(n) , Hbyte(1)
Hbyte(1) = 60 + N
Readeeprom Ds4(n) , Hbyte(1)
Next N
Readeeprom T_min , 2
Readeeprom T_alarm , 4
Readeeprom Hbyte(1) , 6
Tryb_letni = Hbyte(1).0
If T_min < 100 Or T_min > 950 Then T_min = 400
If T_alarm < 100 Or T_alarm > 950 Then T_alarm = 850
Wait 1
Wyswietlono = 1
Wyswietlanie = 1
Autosave = 5
Autolight = 0
'******* Warunki Poczatkowe Koniec ***********
'************** Petla glowna ******************
'***********************************************
Do
'*********************************************** co 4ms
If Flaga_4ms = 1 Then
Flaga_4ms = 0
Gosub Przyciski
If Wyswietlono = 1 Then Gosub Wysw_lcd
End If
'***********************************************
'*********************************************** co 500ms
If Flaga_500ms = 1 Then
Flaga_500ms = 0
Mig = Not Mig
'Portd.6 = Buzz_en
If Pompa = 0 Then Led_p = Mig Else Led_p = 1
If Went = 0 Then Led_w = Mig Else Led_w = 1
Led_a = Buzz
Wyswietlanie = Poz_wysw
End If
'***********************************************
'*********************************************** co 1s
If Flaga_1s = 1 Then
Flaga_1s = 0
If Light = 0 Then
Incr Autolight
If Autolight >= 20 Then Light = 1
Else
Autolight = 0
End If
If Poz_wysw <> 1 Then
Incr Autopowrot
If Autopowrot = 6 Then
'Poz_wysw = 1
Wyswietlanie = 1
Poz_ust = 0
End If
Else
Autopowrot = 0
End If
If Autosave < 5 Then
Incr Autosave
If Autosave = 5 Then
'tu zapis do eeprom
Writeeeprom T_min , 2
Writeeeprom T_alarm , 4
Hbyte(1) = 0
Hbyte(1).0 = Tryb_letni
Writeeeprom Hbyte(1) , 6
Poz_ust = 0
End If
End If
Gosub Temperatura
Gosub Sterowanie
End If
'***********************************************
Loop
End
'************ Petla glowna Koniec **************
'************ Przerwanie timer 0 ***************
'***********************************************
Prztimer0:
Timer0 = 5
Set Flaga_4ms
Incr Dzielnik(1)
If Dzielnik(1) = 125 Then
Dzielnik(1) = 0
Set Flaga_500ms
Incr Dzielnik(2)
If Dzielnik(2) = 2 Then
Dzielnik(2) = 0
Set Flaga_1s
End If
End If
Return
'******** Przerwanie timer 0 Koniec ************
'***********************************************
'***************** Przyciski **************
Przyciski:
Sw = Sw_port And &B00000111 'maska na piny nieu?ywane jako sw
If Sw <> &B00000111 And Stan_sw = Sw Then
Incr Licznik_sw
If Licznik_sw = 68 Then
Licznik_sw = 0
Select Case Stan_sw
Case &B00000011: 'incr
'***********************************************************
Select Case Poz_wysw
Case 3:
Select Case Poz_ust
Case 0:
Poz_ust = 1
Case 1:
If T_min < 950 Then T_min = T_min + 10
Case 2:
If T_alarm < 950 Then T_alarm = T_alarm + 10
End Select
Autosave = 0
Case 4:
If Poz_ust = 0 Then Poz_ust = 1 Else Tryb_letni = Not Tryb_letni
Autosave = 0
'Case 5:
End Select
If Buzz = 0 Then Buzz_en = 0
Autopowrot = 0
Light = 0
Autolight = 0
Case &B00000101: 'ustaw next
'***********************************************************
If Poz_ust = 0 Then
Wyswietlanie = Poz_wysw + 1
If Wyswietlanie = 5 Then Wyswietlanie = 1
Else
Select Case Poz_wysw
Case 3:
Incr Poz_ust
If Poz_ust = 3 Then Poz_ust = 0
Case 4:
Incr Poz_ust
If Poz_ust = 2 Then Poz_ust = 0
End Select
End If
If Buzz = 0 Then Buzz_en = 0
Autopowrot = 0
Light = 0
Autolight = 0
Case &B00000110: 'decr
'***********************************************************
Select Case Poz_wysw
Case 3:
Select Case Poz_ust
Case 0:
Poz_ust = 1
Case 1:
If T_min > 100 Then T_min = T_min - 10
Case 2:
If T_alarm > 100 Then T_alarm = T_alarm - 10
End Select
Autosave = 0
Case 4:
If Poz_ust = 0 Then Poz_ust = 1 Else Tryb_letni = Not Tryb_letni
Autosave = 0
'Case 5:
End Select
If Buzz = 0 Then Buzz_en = 0
Autopowrot = 0
Light = 0
Autolight = 0
End Select
End If
Else
Stan_sw = Sw
Licznik_sw = 60
End If
Return
'***********************************************
'***********************************************
'************** LCD ***********
Wysw_lcd:
If Wyswietlanie <> 0 Then
Wyswietlono = 0
Select Case Wyswietlanie
Case 1: 'temp piec bojler
'**************************************************************
If Poz_wysw <> 1 Then
Deflcdchar 0 , 7 , 5 , 7 , 32 , 32 , 32 , 32 , 32 'stopien
'Deflcdchar 1 , 4 , 32 , 14 , 17 , 17 , 17 , 14 , 32 ' o kreskowane
Cls
Lcd "Piec:"
Lowerline
Lcd "Bojler:"
End If
For N = 1 To 2
Hword(1) = T(n) / 10
Hword(2) = 12
If Hword(1) >= 10 Then Decr Hword(2)
If Hword(1) >= 100 Then Decr Hword(2)
If Minusy.n = 1 Then Decr Hword(2)
Locate N , Hword(2)
Hword(2) = T(n) Mod 10
If Minusy.n = 1 Then Lcd "-"
Lcd Hword(1) ; "." ; Hword(2) ; Chr(0) ; "C"
Next N
Case 2: 'temb banka,dom
'**************************************************************
If Poz_wysw <> 2 Then
Deflcdchar 0 , 7 , 5 , 7 , 32 , 32 , 32 , 32 , 32 'stopien
Cls
Lcd "Zbiornik:"
Lowerline
Lcd "Kuchnia:"
End If
For N = 3 To 4
Hword(1) = T(n) / 10
Hword(2) = 12
If Hword(1) >= 10 Then Decr Hword(2)
If Hword(1) >= 100 Then Decr Hword(2)
If Minusy.n = 1 Then Decr Hword(2)
M = N - 2
Locate M , Hword(2)
Hword(2) = T(n) Mod 10
If Minusy.n = 1 Then Lcd "-"
Lcd Hword(1) ; "." ; Hword(2) ; Chr(0) ; "C"
Next N
Case 3:
'**************************************************************
If Poz_wysw <> 3 Then
Deflcdchar 0 , 7 , 5 , 7 , 32 , 32 , 32 , 32 , 32 'stopien
'Deflcdchar 1 , 4 , 32 , 14 , 17 , 17 , 17 , 14 , 32 ' o kreskowane
Cls
Lcd "T.Min:"
Lowerline
Lcd "T.Alarm"
End If
If Poz_ust = 1 And Mig = 1 Then
Locate 1 , 10
Lcd " "
Else
't minimalna
Hword(1) = T_min / 10
Hword(2) = 12
If Hword(1) >= 10 Then Decr Hword(2)
If Hword(1) >= 100 Then Decr Hword(2)
Locate 1 , Hword(2)
Hword(2) = T_min Mod 10
Lcd Hword(1) ; "." ; Hword(2) ; Chr(0) ; "C "
End If
If Poz_ust = 2 And Mig = 1 Then
Locate 2 , 10
Lcd " "
Else
't alarmowa
Hword(1) = T_alarm / 10
Hword(2) = 12
If Hword(1) >= 10 Then Decr Hword(2)
If Hword(1) >= 100 Then Decr Hword(2)
Locate 2 , Hword(2)
Hword(2) = T_alarm Mod 10
Lcd Hword(1) ; "." ; Hword(2) ; Chr(0) ; "C"
End If
Case 4:
'**************************************************************
If Poz_wysw <> 4 Then
Cls
Lcd "Tryb: "
End If
Locate 1 , 7
If Poz_ust = 1 And Mig = 1 Then
Lcd " "
Else
If Tryb_letni = 1 Then Lcd "Letni" Else Lcd "Zimowy"
End If
Case 5:
'**************************************************************
If Poz_wysw <> 5 Then
Cls
Lcd "Przedmuch:"
Lowerline
Lcd "Przerwa:"
End If
End Select
Poz_wysw = Wyswietlanie
Wyswietlanie = 0
Wyswietlono = 1
End If
Return
'************** LCD Koniec ***********
'********** rejestracja DS *********
Ds_reg:
Disable Interrupts
1wreset
1wwrite &H33
Ds(1) = 1wread(8):
Enable Interrupts
If Ds(1) <> 255 Or Ds(2) <> 255 Or Ds(3) <> 255 Or Ds(4) <> 255 Or Ds(5) <> 255 Or Ds(6) <> 255 Or Ds(7) <> 255 Or Ds(8) <> 255 Then
Ds_ok = 1
For N = 1 To 8
Hbyte(1) = Ds_adr + N
Writeeeprom Ds(n) , Hbyte(1)
Next N
Else
Ds_ok = 0
End If
Return
'****** rejestracja DS Koniec ******
'************* Temperatura ***********
Temperatura:
Disable Interrupts
1wreset
Select Case Ktory_ds
Case 0:
1wwrite &HCC
1wwrite &H44
Case 1:
1wwrite &H55
1wwrite Ds1(1) , 8
1wwrite &HBE
Lsb = 1wread():
Msb = 1wread():
Case 2:
1wwrite &H55
1wwrite Ds2(1) , 8
1wwrite &HBE
Lsb = 1wread():
Msb = 1wread():
Case 3:
1wwrite &H55
1wwrite Ds3(1) , 8
1wwrite &HBE
Lsb = 1wread():
Msb = 1wread():
Case 4:
1wwrite &H55
1wwrite Ds4(1) , 8
1wwrite &HBE
Lsb = 1wread():
Msb = 1wread():
End Select
Enable Interrupts
If Ktory_ds > 0 Then
T(ktory_ds) = Msb * 256
T(ktory_ds) = T(ktory_ds) + Lsb
Minusy.ktory_ds = Msb.7
If Minusy.ktory_ds = 1 Then
T(ktory_ds) = Not T(ktory_ds)
T(ktory_ds) = T(ktory_ds) + 1
End If
T(ktory_ds) = T(ktory_ds) * 10
T(ktory_ds) = T(ktory_ds) / 16
Else
If Poz_wysw = 1 And Wyswietlono = 1 Then Wyswietlanie = 1
End If
Incr Ktory_ds
If Ktory_ds = 5 Then Ktory_ds = 0
Return
'********** Temperatura Koniec *********
'************ Sterowanie ***************
'***********************************************
Sterowanie:
If Tryb_letni = 1 Then
If T(1) >= T_min Then
Hword(1) = T(2) + 70
Hword(2) = T(2) + 30
If T(1) >= Hword(1) Then Pompa = 0
If T(1) <= Hword(2) Then Pompa = 1
Else
Pompa = 1
End If
Else
If T(1) >= T_min Then
Pompa = 0
Else
Pompa = 1
End If
End If
If T(1) >= T_alarm Or T(2) >= T_alarm Then
If Buzz_en = 1 Then Buzz = Not Buzz Else Buzz = 1
Else
Buzz = 1
Hword(1) = T_alarm - 50
If T(1) <= Hword(1) And T(2) <= Hword(1) Then Buzz_en = 1
End If
'tutaj sterowanie wentylatorem
Return
'******** Sterowanie Koniec ************
Ustawienia fusebitów dla mikrokontrolera ATMEGA8 przedstawione są poniżej:
Wstępne uruchomienie sterownika sprowadza się do zaprogramowania czujników z którymi będzie współpracował. Przy wyłączonym zasilaniu rozwieramy zworkę 1W_ENA wkładamy pierwszy czujnik (od pieca) do złącza na płytce (układ U2), rozwieramy zworkę DSR1 i zwieramy DSR2 i DSR3. Włączamy zasilanie a na wyświetlaczu pojawia się napis "Ds Piec" co świadczy o poprawnym odczycie czujnika. W tej chwili temperatura powinna być już odczytywana. Wyłączamy ponownie zasilanie i kontynuujemy rejestrację pozostałych czujników w taki sam sposób, z tym że ustawienia zworek DSR1...DSR3 są inne. Podczas rejestracji do układu może być jednorazowo podłączony tylko jeden czujnik.
Ustawienia zworek:
Piec: DSR1 = 1, DSR2 = 0, DSR3 = 0
Bojler: DSR1 = 0, DSR2 = 1, DSR3 = 0
Zbiornik wyrównawczy: DSR1 = 1, DSR2 = 1, DSR3 = 0
Dom: DSR1 = 0, DSR2 = 0, DSR3 = 1
*"0" oznacza zworkę zwartą, a "1" rozwartą
Po zakończeniu procedury rejestracyjnej czujników podłączamy je wszystkie naraz do układu i umieszczamy w przeznaczonych miejscach. W przypadku zmiany jednego z czujników trzeba go zarejestrować w taki sam sposób pamiętając że wszystkie pozostałe muszą być odłączone (Zworka 1W_ENA).
Ale na wszystkich ładowarka
Ale na wszystkich ładowarka jakie mam w domu (biegałem, szukałem i czytałem) jast napisane na jednej 4,7V na innej 5,8V, a na 3 pozostałych 5,2V więc stabilizatora nie trzeba wrecz nie wolno.
Re: Zasilanie
Po pirwsze i najważniejsze: Układ ma byc zasilany napięciem 5V i nieważne skąd i jak to uzyskasz. jeśli twoja ładowarka bez obciązenia daje ci 5.2V i nie spadnie do 4.5 jak się włączy ototriak i podświetlanie LCD to dobrze. Moja wersja (z napisem na obudowie 5.2V 800mA) dawała coś około 11V po zmierzeniu bez obciążenia, więc najpierw przeprowadź pomiary a potem się zastanawiaj po co jest stabilizator.
Jakby napięcie nie było zbyt wysokie to można zawsze zastosować stabilizator w wersji LDO
UWAGA! Możliwy jest zakup zaprogramowanych uC i zestawów elementów itp. do niektórych projektów. O dostępność proszę pytać via email. Konkretne oferty pojawiają się w cenniku.
Właśnie zmierzyłem i bez
Właśnie zmierzyłem i bez obciążenia jest 8V (na większości) a po obciążeniu 2 atmega 16 na kwarcu 20Mhz (bez problemu ruszyły) i lcd z podświetlaniem jest 5,6V
MOC3041
Witam,
Jestem w trakcie składania sterownika. Mam już polutowany i działający układ sterowania. Teraz robię układ wykonawczy i mam jeden problem, a w zasadzie pytanie, żeby się upewnić. Nigdy nie projektowałem układów, raczej jak już to wykonuje według gotowych projektów:
W układzie zastosowałeś MOC3041. Niestety nie dostałem takiego w moich lokalnych sklepach. Kupiłem natomiast MOC3043. Z tego co widzę różnią one się prądem "LED trigger current", gdzie MOC3041 ma 15mA, a mój MOC3043 ma 5mA. Rozumiem, że muszę zamiast rezystorów 330om dać 1kom? Pozostałe rezystory R2, R3, R5, R6 zostają rozumiem takie same?
Pozdrawiam, Darek
Tak.
Tak.
No i nie działa (układ wykonawczy)
Witam,
po kolei: układa sterowania działa prawidłowo, włącza się dioda POMPA przy ustawionej temp. włączenia, włącza się alarm itd. (ustawiony tryb letni). Teraz podłączyłem układ ster. do układu w wykonawczego, ale bez podłączania ~230V i pompy. Działa prawidłowo, zapala się dioda LED D2 w obwodzie TRO2 przy osiągnięciu temp. włączenia. Tutaj jeszcze raz uwaga: zamiast MOC3041 dałem MOC3043, zmieniłem przy tym rezystory R1 i R4 z 330om na 1kom, ze względu, że prąd "wyzwolenia" MOC 3043 jest 5mA (MOC3041 15mA). Podłączony tylko jeden DS18B20 od pieca. Reszta według schematu. Wszystkie części nowe. Podłączyłem ~230V i pompkę. No i niestety nie działa. Zapalają się diody od pompy, dioda D2 w obwodzie MOC-a, a pompa niestety nie.
Żeby wyeliminować przyczyny: sprawdziłem pompkę - działa prawidłowo, zasilanie 230V działa prawidłowo. Sprawdziłem luty - są OK. Dzisiaj jeszcze sprawdzę w na drugiej "ścieżce" czyli TRO1
Według mnie nie działa coś w obwodzie optoizolacja - triak. Jak to sprawdzić? Jeszcze raz zadam pytanie czy prawidłowo zamieniłem 330om na 1kom. Czy można zamiast ~230V podłączyć ~12-24V? - mam trzech elektryków w rodzinie i wolę uważać z 230V :-)
Jak sprawdzić czy MOC działa?
Pozdrawiam, Darek
Quote:Jeszcze raz zadam
Sprawdź triaka czy na pewno dobrze podłączony.Lepiej sprawdzić po raz 10 może coś przeoczyłeś.Kiedyś miałem trochę inny problem ale też z triakiem i pompą cos nie za bardzo chciało współpracować.
Co cie nie zabije to cie wzmocni.
(Nie dotyczy kondensatora 230V)
Działa połowicznie, czyli
Działa połowicznie, czyli ciąg dalszy walki ze sterownikiem C.O.
Podłączyłem do TRO1 - to samo pompa nie rusza. Zmieniłem rezystor R4 na 810om. Dalej nic. Podłączyłem z ciekawości do "wejścia 230V" napięcie zmienne 16V z transformatora i sprawdzałem woltomierzem na wyjściu TRO2 co się dzieje i... działa. Tzn. temp. rośnie pojawia się 16V na wyjściu. Spada to triak się wyłącza. No to idziemy do piwnicy. Podłączam zasilanie i pompę i... nie działa :-( Kolejny ciekawski krok: wyłączyłem wtyczkę od 230V i po chwili włączyłem i pompa ruszyła - jak temp. spadła pompa się wyłączyła.
Problem w tej chwili jest taki: załączenie triaka nie powoduje startu pompy. Trzeba włączyć i wyłączyć 2-3 razy napięcie zasilające 230V wtedy jest szansa że się załączy. Spadek temp. wyłącza pompę czyli działa prawidłowo.
Co teraz?
W nocie katalogowej MOC-a jest jakiś układ RC: The 39 ohm resistor and 0.01 ?F capacitor are for snubbing of the triac and may or may not be necessary depending upon the particular triac and load used. I jeszcze For highly inductive loads (power factor < 0.5), change this value to 360 ohms. Czyli trzeba dorobić taki układ?
PS. White, dzięki za info. Czy miałeś taki sam problem?
PS2. Pompka to LFP Leszno 3 biegowa.
Pozdrawiam, Darek.
sterownik
hm... nie wiem dokładnie jaki to typ pompy ale u mnie był taki problem że pomimo że układ (jednak to nie ten projekt) działał prawidłowo załączał poprzez moc`a i triaka poprawnie urządzenia 230V to przy obciążeniu pompa układ nie wyłączał triaka w tym czasie kiedy miał.W zasadzie nie chciał wcale wyłączać musiałem to rozwiązać stosując jedno wyjście przekaźnikowe.Sprawdź czy układ załącza bez problemu przy obciążeniu rezystancyjnym czyli zapodaj jakąś żarówkę 50W i sprawdź.Jeżeli będzie działać to problem polega w charakterystyce tego triaka i moca ale tak do końca to sam nie wiem jak ten problem rozwiązać.
Najważniejsze to wiedzieć czy elementy są sprawne więc sprawdź z żarówką.Potem pomyślimy.
Co cie nie zabije to cie wzmocni.
(Nie dotyczy kondensatora 230V)
Z żarówką też nie działa
Z żarówką też nie działa :-(
Chyba przejadę się jutro po MOC3041 i rezystorki 330om tak jak w oryginale.
Pozdrawiam, Darek.
sterownik
Sprawa może wyglądać tak że przez przypadek mogłeś spalić optotriaka one są bardzo wrażliwe i spalić takiego wcale nie trzeba się starać.Jeżeli nie działa z żarówką nie ma co dociekać problemów z pompą.Wymień na nowy i myślę że powinno ruszyć.
Co cie nie zabije to cie wzmocni.
(Nie dotyczy kondensatora 230V)
Triak rzecz dziwna, ja do
Triak rzecz dziwna, ja do takiego celu wolałbym zastosować przekażnik, przynajmniej pewne a co gdy triak sie nie wyłączy i puści cały czas 230 na wentylator ?
Re: Przekaźnik
Zastanowił bym się dwa razy czy przekaźnik jest lepszy.... jak dotąd miałem mnóstwo problemów z przekaźnikami a triak zawsze mi działał. trzeba po prostu stosować elementy jak na schemacie
UWAGA! Możliwy jest zakup zaprogramowanych uC i zestawów elementów itp. do niektórych projektów. O dostępność proszę pytać via email. Konkretne oferty pojawiają się w cenniku.
A jednak działa ten triak :)
Witam ponownie.
Poczytałem wczoraj i dzisiaj trochę o MOC-ach, obliczaniu rezystorów do diod LED itp. i z moich obliczeń wynika, że trzeba dać mniejszy rezystor R1 i R4 w przypadku MOC3043 (prąd wysterowania to 5mA). Mniej więcej wychodzi to tak, że:
-zasilanie MOC-a to 5V;
-spadek napięcia na czerwonej diodzie LED D1 lub D2 to około 1,75-2V (czasami 2,2v) czyli na MOC-a zostaje 3-3,25V (3,25V - tyle mi pokazywał woltomierz na nóżce MOC-a). Czyli 3,25V/0,005A=650om. Nie uwzględniłem spadku napięcia na LEDzie MOC-a (nie wiem czy powinno się uwzględniać). Dałem rezystor 560om, czy prąd popłynie w najgorszym wypadku 0,0058A czyli 5,8mA. Prąd wyzwolenia dla tego MOC-a to 5mA. Chyba nie powinno się nic stać.
W każdym bądź razie działa. Sprawdzone najpierw na żarówce ~18V potem na 100W 230V :-) Działa ładnie włącza i wyłącza zgodnie z ustawioną temp. załączenia :-) Przetestowane kilkanaście razy.
PS. Mirley, skoryguj mnie, jeżeli jakaś bzdurę napisałem, bo nigdy nie zajmowałem się projektowaniem i obliczaniem układów elektronicznych. I napisz skąd wytrzasnąłeś taki sposób połączenia MOC-a z triakiem, bo na notach katalogowych jest inaczej :-)
PS2. Cieszę się bardzo z tego sterownika. Podziękowania przy okazji za ten i inne projekty.
Pozdrawiam, Darek.
Re: Sterownik CO
Rezystor który przeważnie jest jeden na bramce triaka rozdzieliłem na dwa, podobno lepiej działa zgodnie z informacją na jakimś forum. W najprostszym przypadku wystarczy jeden rezystor.
Co do prądu optotriaka to jak będzie trochę wiekszy to się nic nie stanie. Producent podaje minimalny prąd zadziałania. ja przeważnie dobieram ten rezystor na oko :) Nic nie licząc, ogólnie najlepiej jest zmierzyć prąd jaki płynie i dobrać rezystor.
UWAGA! Możliwy jest zakup zaprogramowanych uC i zestawów elementów itp. do niektórych projektów. O dostępność proszę pytać via email. Konkretne oferty pojawiają się w cenniku.
Ale przekaźnik dopóki mu się
Ale przekaźnik dopóki mu się styki nie zlepią ( co w tym układzie niemożliwe ) to musi rozłączyć i nie ma mocnych ( no chyba że tranzystor się nie zatka ) więc co masz na myśli " miałem z nimi mnóstwo problemów" pole magnetyczne jakie wywołują bo chyba nie prąd jaki pobierają skoro opto wcale nie bierze mniej, no chyba że właśnie lepiące styki ale triak przy dużych prądach się grzeje, natomiast jaki może być problem przy małych prądach?
Sprawdziłem jeszcze dla
Sprawdziłem jeszcze dla pewności z pompką. Też działa :-)
W ostatecznej wersji miałem zrobić na MOC3041, ale byłem dzisiaj po drodze w dwóch wrocławskich sklepach elektronicznych i nie mieli niestety MOC3041. Gdyby ktoś robił taki sterownik i miał tylko MOC3043 to dla rezystora R1 i R4 o wartości 620om (prąd z obliczeń około 5,2mA) też działa prawidłowo. Sprawdzone.
Muszę dorobić jeszcze jeden bok obudowy i może jak czas pozwoli wrzucę parę zdjęć mojego sterownika na forum.
Pozdrawiam, Darek.
Re: Przekaźnik
Chodzi mi o zakłócenia które wytwarzają w układzie. Robiłem raz projekt gdzie dałem w obudowie dwa duże styczniki, niestety co jakiś czas wszystko się zawieszało, a zależało mi na tym żeby procesor nie resetował się ani nie zwieszał. Od tej pory w 90% przypadków stosuję triaki, przy mocach do 500W nagrzewanie triaka można pominąć, wystarczy odpowiednio większy prąd
UWAGA! Możliwy jest zakup zaprogramowanych uC i zestawów elementów itp. do niektórych projektów. O dostępność proszę pytać via email. Konkretne oferty pojawiają się w cenniku.
Termopara
Witam,
Czy można do w/w układu podłączyć zamiast DS18B20 termoparę ponieważ chciałem mierzyć temperaturę do 350C?
Pozdrawiam
Re: Termopara
Nie da się w prosty sposób tego przerobić, trzeba zastosować wzmacniacz pomiarowy do tej termopary a potem podać to na ADC w mikrokontrolerze
UWAGA! Możliwy jest zakup zaprogramowanych uC i zestawów elementów itp. do niektórych projektów. O dostępność proszę pytać via email. Konkretne oferty pojawiają się w cenniku.
problem lcd
Witam! Wlasnie zlozylem sterownik zaprogramowalem tmega a tu nic.
wyswietlacz pokazuje mi same kwadraciki w pierwszej lini i nie moge sobie z tym poradzic.
wyswietlacz to wz1602a wiec teorwtycznie powinien dzialac a nie chce. wkurza mnie to okropnie bo duzo pracy w to wszystko wlozylem. prosil bym o jakas ewentualna rade co i jak. Moze ktos sie zspotkal juz z takim problemem
Pozdr.
Re: LCD
Nazwa twojego LCD nic nie mówi.... ale czy ustawiłeś kontrast potencjometrem? Sprawdź linie sygnałowe do wyświetlacza czy na pewno przewodzą.
UWAGA! Możliwy jest zakup zaprogramowanych uC i zestawów elementów itp. do niektórych projektów. O dostępność proszę pytać via email. Konkretne oferty pojawiają się w cenniku.
lcd problem
Przepraszam wyświetlacz to WC 1602a0 tak na nim jest napisane i podobno powinien działać ale nie chce. Linie są na 100% dobrze chyba z 1000 razy sprawdzałem. wyczytałem gdzieś że je napewno zgodny Z hd44780 a wiec musi być dobrze. Dodatkowo znalazłem info żeby zmienić czasy inicjacji tego lcd. Gdzie to można zrobić u w programie.
pozdr
Re: LCD
Ciekawa sprawa, niestety nie pomogę w tej sprawie bo nie mam pojęcia jak zmienić czasy inicjalizacji, w bascomie do LCD są gotowe procedury więc nie pisałem niczego do obsługi LCD samodzielnie.... nie spotkałem się tez z takim problemem. Gdzie kupiłeś taki wyświetlacz?
UWAGA! Możliwy jest zakup zaprogramowanych uC i zestawów elementów itp. do niektórych projektów. O dostępność proszę pytać via email. Konkretne oferty pojawiają się w cenniku.
Witam, sprawdź P1 od
Witam,
sprawdź P1 od kontrastu czy jest dobrze ustawiony - jak pisze Mirley. Mam chyba (muszę w domu sprawdzić) podobny wyświetlacz wc1602a i nie było z nim żadnych problemów - poza oczywiście regulacją kontrastu :-)
Pozdrawiam, Darek.
problem lcd
LCD kupiłem normalnie w sklepie. Ale jeśli o to chodzi sprawa już rozwiązana wyświetlacz wystartował tylko musiałem troszkę fuse bity pozmieniać a mianowicie zwolnić troszeczkę kontroler bo inaczej był za szybki do tego wyświetlacza i zanim ten zdążył coś wyświetlić to już następowała zmiana itd. W każdym bądź razie teraz wszystko działa jak powinno. teraz tylko poskładać wszystko w obudowy, przerobić piec założyć dmuchawę i będzie cacy. Jak wszystko zmontuje to wystawię zdjęcia ażeby przedstawić mój sposób wykonania.
Poazdr i dziękuje serdecznie
Sterownik
Cześć !!!
Mój sterownik działa i pracuje juz z piecem pozostał mi ostatni element do zainstalowania, mianowicie elektrozawór odcinający bojler, i przeszukując sieć za w/w ustrojstwem doznałem szoku cenowego tzn. najtańszy elektrozawór na przyłącze 1 cala nie schodzi poniżej 4,5 stówy !!!, może ktoś z was zna miejsca gdzie można nabyć takie coś w nieco niższej cenie.
Dodaje jeszcze zdjęcia:
Układ wykonawczy został wykorzystany z uszkodzonego sterownika ośw. ulicznego CPA3.1 Płyta zawierała juz w sobie zasilacz i dwukanałowy obwód sterowania, który idealnie pasował do wspomnianego sterownika.
Sam sterownik zostanie zainstalowany w pokoju tj. zaraz za prezentowaną ścianą.
Do Admina: proszę usunąć zdublowany wątek Nr #28
Pozdrawiam Darek
prosze o pomoc
Witam. Chciałem zbudować pana sterownik. Niestety jestem początkującym elektronikiem i nie wiem jak wykorzystać kodu źródłowy .Czy można prosić o program po kompilacji (BIN)ewentualnie o pomoc w zrobieniu tego samemu..
Re: Sterownik C.O
Kod źródłowy wystarczy otworzyć w programie bascom AVR i kliknąć kompiluj. Trzeba mieć pełną wersję bascoma aby to skompilować.
UWAGA! Możliwy jest zakup zaprogramowanych uC i zestawów elementów itp. do niektórych projektów. O dostępność proszę pytać via email. Konkretne oferty pojawiają się w cenniku.
elektrozawór
Też się lekko zdziwiłem patrząc na ceny takich elektrozaworów. Znalazłem w cenie około 300-350 brutto, np.:
ESM 86 - 086004, DN 1", 230 V AC
Normalnie zamknięty (otwarty pod napięciem)
Korpus mosiądz CW 617 N - PS : 10 bar,
Części wew. nierdzewne
?P mini 0,3 bar - Membrana NBR TS : 80 °C
Temperatura zewnętrzna max: 60 °C.
Membrana EPDM i FPM w opcji do 2"
Cewka izolacja klasa F, wtyk T30 - FT 8600.
230 V AC, 50 Hz, DN 1", FAF 100mm , Przelot 25mm , Przepływ 9,60m3/h
nie wiem czy taki się nadaje, bo są elektrozawory pośredniego działania i bezpośredniego działania, wymagające różnicy ciśnień i nie - nie za bardzo czuję temat.
Nie podaję nazwy sklepu ale myślę, że łatwo sobie wyszukasz (jak nie to pisz na priv).
Pozdrawiam, Darek.
A ja kiedyś myślałem żeby
A ja kiedyś myślałem żeby zastosować zawór z pralki automatycznej tylko nie wiem czy wytrzymałby taką temperaturę?Ostatecznie zrobiłem zamykanie silnikem krokowym i długą śrubą ale zawór po kilku tygodniach zaczął przeciekać.
A po co sobie utrudniać.Ja
A po co sobie utrudniać.Ja zastosowałem mechanizm od elektrycznych szyb samochodowych.
Możesz coś więcej napisać o tych podnośnikach do szyb?
Romariusz: możesz coś więcej napisać o tych podnośnikach do szyb?
Co za różnica, chodzi o to że
Co za różnica, chodzi o to że zwykły zawór kulowy po częstym zamykaniu a w szczególności gdzie raz jest zimno(~10*C) a raz gorąco(~80-90*C) zaczyna ciec.
głowica
Wystarczy montaż zaworu termostatycznego i do tego np to http://www.conrad.pl/websale7/G%b3owica-termostatyczna-EberleTS-230-V.htm?Ctx={ver/7/ver}{st/3eb/st}{cmd/0/cmd}{m/websale/m}{s/conrad/s}{l/01-aa/l}{mi/SHOP_AREA_37360_0812040/mi}{pi/611275/pi}{po/1/po}{fc/x/fc}{p1/857dec0344674bac51c1edb4a53c5963/p1}{md5/70ef0e54516b91239b1cec4c514d505d/md5} możliwość sterowania zewnętrznym sygnałem.
Złącze prog
Jeżeli chce zaprogramować atmege na gotowym juz sterowniku to rozwieram zworki do ustawienia czujników .Podłączam według wyjść atmegi i mogę programować?.Co z GDN które wyprowadziłeś tez jako wyjście goldpin mam podpiać je pod GND z którego jest zasilany sterownik ?
Re: Programoanie C.O.
Do programator amasz podłaczyć wszystkie piny do programowania MOSI, MISO SCK RST (na osobny pinie jest) i masy GND programatora i sterownika muszą być zwarte. Zasilanie może być zewnętrzne takie jak docelowo będzie, nie możesz wtedy podać zasilania z programatora
UWAGA! Możliwy jest zakup zaprogramowanych uC i zestawów elementów itp. do niektórych projektów. O dostępność proszę pytać via email. Konkretne oferty pojawiają się w cenniku.
super sprawa !!
Właśnie cos podobnego potrzebuje tylko do podnoszenia klapki ciągu - powinno się nadac.
A jak nie to moze troszke przerobie. Interesuje mnie sterowanie otwierania klapki przez silnik krokowy z braku miejsca instalacji czego innego (piec w kacie przy w samym wejsciu).
wielkie dzieki
Jeżeli chcesz tylko sterować
Jeżeli chcesz tylko sterować klapką to w zupełności wystarczy AVT950.I nie potrzeba żadnego krokowca.Wystarczy silniczek z przekładnią sterowany po przez dwie krańcówki.
Kolego, kolega oferuje kit
Kolego, kolega oferuje kit który kosztuje 92.00 zł i do tego pisze:
Więc następnym razem proszę nie pisać takich "złych rzeczy dla początkującego".
Witam
Kolega ma racje chodzi o koszty . Gotowca moge kupic za 330- 350zl i to nie jest to . Jak wspomnialem chodzi mi glownie o brak miejsca. a silniczek napdzal by srube regulacyjna -powinien wystarczyc sam silniczek lub z mala przekladnia - tego mam z rozbiurek drukarek i innych urzadzen . chodzi o zaprogramowanie z iloscia obrotow otwarcia bez wentylatora i pompy aczkolwiek moze kiedys jak przerobie co to sie przyda.
moze pomysle nad wylacznikiami krancowymi i wykorzystam tem pomysl( wiecej zabawy).
pozdrawiam
Wyswietlacz
Złożyłem wszystko fajnie.Zaprogramowałem z Twojego opisu Atmege wszystko niby ok ale na wyświetlaczu mam tylko 1 górna linijkę i to nie teks tylko zapełnione cale pixelami.Wiem gdzie chyba źle podłączyłem ale nie jestem pewien.Na płytce sterownika jest tylko 15 wyjść a na wyświetlaczu jest 16 i właśnie 16 został mi pusty...Jak podłączyć wyświetlacz ?
Rejestrowanie czujnikow
Zobacz sobie na schemat w opisie jest
Re: Wyświetlacz
Spraw ustawienie kontrastu wyświetlacza za pomocą potencjometru. Sprawdź połączenia i zwarcia...
Chyba wiem w czym może być problem... na płytce masz złącze 16pin takie samo jak w wyświetlaczach 16x2, z tym że pin 9 jest usunięty i nie ma dziury na niego na płytce. Podłaczając kablem musiałeś się pomylić licząc piny. Wywietlacz powinien byc zamontowany bezpośrednio do płytki za pomocą złącza szufladkowego, wtedy o takiej pomyłce nie było by mowy
UWAGA! Możliwy jest zakup zaprogramowanych uC i zestawów elementów itp. do niektórych projektów. O dostępność proszę pytać via email. Konkretne oferty pojawiają się w cenniku.
Czy w projekcie można
Czy w projekcie można zastosować atmega8 (wersja L)?
Re: Sterownik C.O
Może byc wersja L jednak z założenia przeznaczone sa one do pracy z max 8MHz.... wiekszość działa na 16MHz ale to tylko z przypadku. Pewniej będzie zmienic w projekcie taktowanie na 8MHz i timer tak zmienic żeby przerwanie było dalej co 4ms
UWAGA! Możliwy jest zakup zaprogramowanych uC i zestawów elementów itp. do niektórych projektów. O dostępność proszę pytać via email. Konkretne oferty pojawiają się w cenniku.
Temperatura
wykonałem płytkę i wszystko zgodnie z projektem leca mam problem - nie wyświetla sie aktualna temperatura po rejestracji DS ,wymieniałem już dwa razy atmege i DS18b20 i dalej to samo . Pytanie zworki po rejestracji DSów maja byc załone - czy zdjete.
Re: Sterownik C.O
Podczas normalnej pracy zworki mają być albo wszystkie zdjęte albo wszystkie założone, kombinacje do rejestracji poszczególnych czujników przedstawione są wyżej. Podłączasz jeden czujnik np ten co będzie do pieca (reszta odłączona), ustawiasz zworki zgodnie z opisem, włączasz zasilanie pojawia się napis "Ds piec", wyłączasz zasilanie i wyciągasz ds'a. Wkładasz drugiego, ustawiasz zworki w innej kombinacji np na Kuchnia, włączasz zasilanie i pojawia się napis "Ds Kuchnia", wyłączasz zasilanie wyciągasz czujnik.... itd.
UWAGA! Możliwy jest zakup zaprogramowanych uC i zestawów elementów itp. do niektórych projektów. O dostępność proszę pytać via email. Konkretne oferty pojawiają się w cenniku.
Temperatura
tak tez robiłem alepomimo kilkunastu prób nic ztego . przt rozpoznaniu czujników pojedyncz wyswietlaja sie odpowiednio napisy piec itd .
to jest opisane uwazam ze dosc zrozumiale .
tylko dlaczego jak piszesz po rozpoznaniu czujnika nie ma pomiaru tem. ( przed zerami sa minusy) czy to cos oznacza .
A moze cos nie tak robie ?????
moze zatrzymajmy sie na jednym czujniku - jak jeden zaskoczy to i pozostałe tez.Czy wina DS18B20. czy bład podczs programowania megi ale to druga i nic .
Re: C.O
Jeden czujnik tez powinien działać.... masz dobrze ustawione fusebity w M8? według rysunku na stronie. Czy rezystor 4,7k jest zamontowany i czy ma odpowiednią wartość? Jak pojawia sie napis DS piec to jeszcze nic nie znaczy.... powinna pojawic sie temperatura z czujnika w miejscu gdzie jest wyświetlanie temperatury pieca. Jesli czujnik jest dobry i wszystko na płytce jest dobrze podłączone.... gdzie wkładasz czujnik na czas rejestracji? jest połączenie od pinu sygnałowego do procesora?
UWAGA! Możliwy jest zakup zaprogramowanych uC i zestawów elementów itp. do niektórych projektów. O dostępność proszę pytać via email. Konkretne oferty pojawiają się w cenniku.