Termometr Uniwersalny


9.28571
Ocena: None Średnia: 9.3 (14 głosujących)

Termometr ten pracuje w zakresie temperatur od -50.0 do +99.9 stopni lub w drugiej wersji oprogramowania aż do +125 stopni. Układ został zaprojektowany do mierzenia temperatury w akwarium ale z powodzeniem można dla niego znaleźć wiele innych zastosowań. Na płytce znajduje się miejsce na dwa przyciski oraz dodatkowe złącze ogólnego przeznaczenia. Po zmianie oprogramowania urządzenie może pełnić funkcję prostego termostatu, lub bardziej złożonego regulatora temperatury. Układ został zbudowany w oparciu o popularny, często stosowany czujnik DS18B20 i mikrokontroler AT89C2051 co znacznie uprościło jego konstrukcję i zmniejszyło wymiary. W układzie można też bez większego trudu zastosować mikrokontroler ATTiny2313, wymaga to tylko wprowadzenia kilku prostych modyfikacji.

Działanie:


Schemat termometru przedstawia poniższy rysunek:

Sercem urządzenia jest mikrokontroler U2 (AT89C2051) wraz z rezonatorem kwarcowym X1 (12MHz) i dwoma kondensatorami C4 (33pF) i C5 (33pF). Kondensator C3 (1uF) resetuje procesor po włączeniu napięcia zasilającego, a C1 (220uF) filtruje to napięcie. Do złącza zas podłączamy napięcie zasilające o wartości 5V. Rezystory R9 - R16 (330R) ograniczają prąd wyświetlaczy. Tranzystory T1 - T3 (BC557B) wraz z rezystorami R1 - R6 (3,3k) sterują anodami wyświetlaczy.

Budowa:


Termometr można zbudować z wykorzystaniem dostępnej tutaj płytki drukowanej. Wersja płytki w odbiciu lustrzanym dostępna jest tutaj. Montaż elementów można dokonać w dowolnej kolejności, najlepiej od najmniejszych do największych. Pod wyświetlacz dobrze jest wlutować kawałek podstawki DIP40, natomiast pod mikrokontroler podsatwka jest bezwzględnie konieczna. Od strony druku należy wlutować rezystor 4,7k podciągający magistralę 1-Wire (nóźka 9 układu U2) do plusa zasilania. Złącze GP1 w wersji podstawowej służy do podłączenia diody sygnalizującej ujemną temperaturę (katodą do portu procesora, anodą do VCC) gdyby miało być wykorzystywane w inny sposób należy usunąć z kodu programu linijkę: P3.7 = Not Minus. Przód obudowy można z powodzeniem wykonać z kawałka laminatu. Płytkę termometru mocujemy do panelu przedniego za pomocą dwóch przylutowanych do niego śrub. Pomocą przy konstrukcji może okazać się schemat montażowy dostępny tutaj.

Jeżeli w układzie będzie zastosowany mikrokontroler ATTiny2313 zamiast AT89C2051, nie należy montować kondensatora C3, a kondensatory C4 i C5 powinny mieć wartość 22pF.

Wykaz Elementów:

8x 330R
6x 3,3k

2x 33pF
1x 1uF
1x 220uF

1x Rezonator Kwarcowy 12MHz
1x AT89C2051 (lub ATTiny2313)
3x BC557B
1x DS18B20
1x AT5636BG-B Pb-free (TOT-5362BG-B) Wyświetlacz potrójny

Programowanie:


Oprogramowanie do termometru zostało napisane w wersji demo programu BASCOM 8051 firmy MCS Electronics (http://www.mcselec.com/). Program w całości przedstawiony jest poniżej:

'****************************
           'Konfiguracja
'****************************
$crystal = 12000000                                           '12MHz
$regfile = "89C2051.DAT"
 
Config 1wire = P3.5
 
Config Timer0 = Timer , Gate = Internal , Mode = 2
On Timer0 Przerwanie0
Load Timer0 , 250
Enable Timer0
Start Timer0
 
Enable Interrupts
'****************************
      'Zmienne
'****************************
Dim Lsb As Byte
Dim Msb As Byte
Dim Co4ms As Byte , Co100ms As Byte , Co1s As Byte
Dim Wysw As Word , Wysw1 As Byte , Wysw10 As Byte , Wysw100 As Byte
Dim Tempa As Word
Dim Mux As Byte
 
Dim Zezw_wysw As Bit
Dim Pomiar_odczyt As Bit
Dim Minus As Bit
Dim Ur As Bit
'****************************
      'Wartosci Poczatkowe
'****************************
Reset Pomiar_odczyt
Reset Ur
Wysw1 = 191
Wysw10 = 191
Wysw100 = 191
'****************************
      'Petla glowna
'****************************
Do
 
If Zezw_wysw = 1 Then
  Reset Zezw_wysw                                             'co 4ms
  Wysw = Tempa
 
  If Ur = 1 Then Gosub Przelicz
  Gosub Wyswietl
End If
 
Loop
End
'****************************
      'Przerwanie timer0
'****************************
Przerwanie0:
Incr Co4ms
 If Co4ms = 16 Then
   Co4ms = 0
   '***************************************  co 4ms
   Set Zezw_wysw
   Incr Co100ms
   If Co100ms = 25 Then
     Co100ms = 0
     '*************************************** co 100 ms
     'ew flaga obslugi przyciskow
     Incr Co1s
     If Co1s = 7 Then
       Co1s = 0
       '*************************************** co 1s
       Pomiar_odczyt = Not Pomiar_odczyt
 
       Disable Interrupts
       1wreset
 
       If Pomiar_odczyt = 1 Then
        1wwrite &HCC
        1wwrite &H44
       Else
        If Err = 0 Then
 
          1wwrite &HCC
          1wwrite &HBE
          Lsb = 1wread():
          Msb = 1wread():
 
          Minus = Msb.7
 
          Tempa = Msb * 256
          Tempa = Tempa + Lsb
 
 
          If Minus = 1 Then
            Tempa = Not Tempa
            Tempa = Tempa + 1
          End If
 
          Tempa = Tempa * 10                                  'temperatura *10
          Tempa = Tempa / 16
 
          If Ur = 0 Then Ur = 1
 
        Else
          Tempa = 10000                                       'Er wyswietli wyswietlacz potem
        End If
       End If
 
       Enable Interrupts
       '***************************************
     End If
     '***************************************
   End If
   '***************************************
 End If
 
Return
'****************************
      'Inne Etykiety
'****************************
Przelicz:
 If Wysw < 1000 Then
   Wysw1 = Wysw Mod 10
   Wysw = Wysw / 10
   Wysw10 = Wysw Mod 10
   Wysw = Wysw / 10
   Wysw100 = Wysw Mod 10
 
   If Wysw100 = 0 Then Wysw100 = 10                           'wygaszenie zera wiodcego
 
   Wysw1 = Lookup(wysw1 , Tabela)
   Wysw10 = Lookup(wysw10 , Tabela2)
   Wysw100 = Lookup(wysw100 , Tabela)
 
 Else
   Wysw1 = 175                                                'r
   Wysw10 = 175                                               'r
   Wysw100 = 134                                              'E
 End If
 
Return
 
Wyswietl:
  Incr Mux
  If Mux = 3 Then Mux = 0
  P3.7 = Not Minus
 
  Select Case Mux
    Case 0:
     Set P3.0
      P1 = Wysw100
     Reset P3.2
 
    Case 1:
     Set P3.2
      P1 = Wysw10
     Reset P3.1
 
    Case 2:
     Set P3.1
     P1 = Wysw1
     Reset P3.0
  End Select
Return
 
                         'Tabele do wyswietlania na wyswietlaczu
Tabela:
    Data 192 , 249 , 164 , 176 , 153 , 146 , 130 , 248 , 128 , 144 , 255
'znak:    0     1     2     3     4     5     6     7     8     9     pusty
 
Tabela2:
    Data 64 , 121 , 36 , 48 , 25 , 18 , 2 , 120 , 0 , 16 , 255
'znak:    0.    1.  2.    3.   4.   5.  6.   7.   8.  9.    pusty

Ustawienia Fusebitów dla mikrokontrolera ATTiny2313:

Zdjęcia Projektu:

ZałącznikWielkość
Schemat87.5 KB
Płytka11.03 KB
Płytka (odbicie lustrzane)11.01 KB
Płytka (6 na stronie)61.72 KB
Montowanie15.44 KB
Kod źródłowy (wersja podstawowa)4.46 KB
Program po kompilacji (BIN) (wersja podstawowa)1.03 KB
Program po kompilacji (HEX) (wersja podstawowa)2.96 KB
Kod źródłowy (obsługuje temperatury powyżej 100 stopni)4.91 KB
Kod Źrodłowy (wersja z termostatem) (jeszcze nie testowana)7.57 KB
Program po kompilacji (wersja z termostatem) (BIN)1.72 KB
Program po kompilacji (wersja z termostatem) (HEX)4.85 KB
Kod Źródłowy (dla ATTiny2313, Bascom AVR)4.43 KB
Kod Źrodłowy (wersja z termostatem, dla ATTiny2313, Bascom AVR) (jeszcze nie testowana)7.28 KB
Program po kompilacji (BIN) (dla ATTiny2313, Bascom AVR)1.59 KB
Program po kompilacji (HEX) (dla ATTiny2313, Bascom AVR)4.49 KB
Kod źródłowy (dla ATMega8, Bascom AVR)4.6 KB
Nadruk na obudowę64.22 KB



Portret użytkownika mirley

Re: Tranzystory

No dobrze że tranzystory nie przewodzą bo nie powinny

Quote:
....Daje +5 na PD0 i minus na pb0 - pb7 ....

Dobrze popatrz na schemat,tranzystor pnp włącza się niskim potencjałem, przy 5V nie ma prawa przewodzić

ps. Czego nie zrozumiałeś wstwierdzeniu żeby nie pisać posta pod postem..... więcej tegonie scalam bocoraz więcej osób ma to gdzieś i pisze wszystko byle jak

-

UWAGA! Możliwy jest zakup zaprogramowanych uC i zestawów elementów itp. do niektórych projektów. O dostępność proszę pytać via email. Konkretne oferty pojawiają się w cenniku.

Portret użytkownika Początkujący

A co jest nie tak gdy

A co jest nie tak gdy wyświetla tylko '- - -' i mocno miga. Na oprogramowaniu termometr i termostat jest to samo.

---

Dzięki za pomoc! Naprawdę świetna strona.

Wszystkie problemy związane były z moją niewiedzą. Uczę się i to mój pierwszy projekt. Nie wyłączyłem dzielenia częstotliwości przez 8. Sorki za wszystkie problemy i głupie pytania.

Pozdrawiam!

Portret użytkownika poszu

5v na bazie tranzystora?

zrobilem ten uklad tylko ze z innym wyswietlaczem tez wspolna anoda i nie dziala zmierzylem miernikiem ze na bazie jest 5v i jak czytalem tranzystor sie otwiera jako 0v sprawdzilem polaczenia i powinny byc dobre bo mam tak jak na schemacie z procka na rezystor na baze potem kolektor na wyswietlacz anoda a potem katoda do proca oczywiscie dodatkowy rezystor na baza emiter. Jakies pomysly co moze byc nie tak?

Portret użytkownika Poszu

5v na bazie tranzystora? kontynuacja

Z góry przepraszam za 2 posty pod soba.

Cofam wszystko co tu powiedzialem ;)
termometr działa wymienilem procka na nowy i smiga

Portret użytkownika gosc123456cd

atmega8

Witam czy mógłbyś wstawić kod do programu pod atmega8?

Portret użytkownika mirley

RE: Termometr

kod pod mega8 jest wstawiony. katody są na porcie D, anody na pinach C0-C2, na C3 minus. Czujnik do pinu C5

-

UWAGA! Możliwy jest zakup zaprogramowanych uC i zestawów elementów itp. do niektórych projektów. O dostępność proszę pytać via email. Konkretne oferty pojawiają się w cenniku.

Portret użytkownika gosc123456cd

atmega8

A będzie działał ten termometr na wewnętrznym oscylatorze?

Portret użytkownika mirley

Termometr

Powinien działać, ale trzeba w kodzie zmienić definicję oscylatora, z 12000000 na 8000000 i ustawić na wewnętrzny oscylator bez podzielnika częstotliwości. Timer należy tak zmodyfikować aby procedury w programie wywoływały się z tą sama częstotliwością co w oryginalnym programie

-

UWAGA! Możliwy jest zakup zaprogramowanych uC i zestawów elementów itp. do niektórych projektów. O dostępność proszę pytać via email. Konkretne oferty pojawiają się w cenniku.

Portret użytkownika gosc123456cd

atmega8

A jak będzie ustawiony 1MHz to będzie działał, i jak należy zmodyfikować ten timer? Nie wystarczy tylko zmienić deklaracje taktowania?

Portret użytkownika mirley

Re: Timer

Nie wiem czy będzie działać....sam sprawdź. Nie wykonuje testów na wszystkich częstotliwościach. W przerwaniu timera zmień:

Timer0 = 5
Incr Co4ms
 If Co4ms = 3 Then
   Co4ms = 0

na:

Timer0 = 194 
Incr Co4ms
 If Co4ms = 1 Then
   Co4ms = 0

Potem można wogóle ten dzielnik ze zmienną Co4ms wyrzucić.

oczywiście w linijce z Crystal powinno być 1000000

-

UWAGA! Możliwy jest zakup zaprogramowanych uC i zestawów elementów itp. do niektórych projektów. O dostępność proszę pytać via email. Konkretne oferty pojawiają się w cenniku.

Portret użytkownika gosc123456cd

atmega8

Termometr działa na wewnętrznym oscylatorze 1MHz, mam jednak pewien problem a mianowicie że cyfry nie świecą z jednakową jasnością, tzn. np. wyświetlana jest 7 i każdy segment świeci jednakowo a np. 3 świeci jasno środkowy segment a reszta świeci blado.
Jak powinny być ustawione fusebit dla atmegi8 z zewnętrznym kwarcem 12MHz?

Portret użytkownika mirley

Re: Termometr

Tutaj masz opis fusów fuse_bity_w_mikrokontrolerach_avr

-

UWAGA! Możliwy jest zakup zaprogramowanych uC i zestawów elementów itp. do niektórych projektów. O dostępność proszę pytać via email. Konkretne oferty pojawiają się w cenniku.

Portret użytkownika gosc123456cd

atmega8

Czy tak są dobrze ustabione fusbity dla atmegi8 z kwarcem 12Mhz i czy "CKOPT" powinien być zaznaczony czy nie?

Portret użytkownika mirley

Re: Fusy

CKOPT zaznaczony, przecież masz zrzut pod wskazanym linkiem

-

UWAGA! Możliwy jest zakup zaprogramowanych uC i zestawów elementów itp. do niektórych projektów. O dostępność proszę pytać via email. Konkretne oferty pojawiają się w cenniku.

Portret użytkownika gościiiiiii

Atmega8

Co może być powodem że palą się tylko środkowe segmenty?

Portret użytkownika mirley

Re: Termometr

Brak czujnika lub brak rezystora podciągającego o wartości 4,7k między linia sygnałową czujnika a +5V. To są pierwsze dwie możliwości

-

UWAGA! Możliwy jest zakup zaprogramowanych uC i zestawów elementów itp. do niektórych projektów. O dostępność proszę pytać via email. Konkretne oferty pojawiają się w cenniku.

Portret użytkownika drowning_man

odp

Witam,
jak należy przerobić kod (dla attiny2313) aby podłączyć dwa czujniki i wyświetlać temperature z jednego i z drugiego na przemian co np 5s?

Portret użytkownika mirley

Re: Termometr

Całkowicie trzeba przerobić kod ponieważ przy dwóch czujnikach trzeba wysyłać cały numer seryjny danego czujnika.... przez to wyświetlacz będzie przygasał na czas wysyłania i będzie to głupio wyglądało. Rozwiązaniem są dwa ds'y na dwóch osobnych pinach albo takie przerobienie kodu programu żeby wysyłal baj to bajcie na 1-wire bez wyłączania przerwań procka

-

UWAGA! Możliwy jest zakup zaprogramowanych uC i zestawów elementów itp. do niektórych projektów. O dostępność proszę pytać via email. Konkretne oferty pojawiają się w cenniku.

Portret użytkownika ziko234

Termostat

Witam
Zrobiłem ten układ i chcę żeby działał jako termostat. Niestety przy pomiarze temperatury pojawiają się nagle niepożądane cyfry np. jak jest 8,7stopnia i dotykam palcem w celu ogrzania i pokazuje 79,9stopnia przez kilka sekund. Druga usterka to przy kliknięciu switcha pojawia się wartość ale nie ma normalnej regulacji np jak klikam to jest 30, 32, 39, 33, 32, 41 chociaż powinno cały czas rosnąć.
Co jest nie tak? Wina w budowie czy błąd w programie? wgrany jest "Kod Źrodłowy (wersja z termostatem) (jeszcze nie testowana)"
Pozdrawiam

Portret użytkownika mirley

Re Termostat

Spróbuj wgrać program ponownie, sprawdź czy DS dobrze styka i czy nie ma gdzieś nepewnego połączenia, rezystor podciągający DS,a (4,7k) jest dobrze wlutowany?

-

UWAGA! Możliwy jest zakup zaprogramowanych uC i zestawów elementów itp. do niektórych projektów. O dostępność proszę pytać via email. Konkretne oferty pojawiają się w cenniku.

Portret użytkownika ziko234

Termostat

Witam przeprogramowałem jeszcze raz uC i nadal to samo. Może źle to robię? W bascomie 8051 kliknalem najpierw na compile, potem na erace chip, następnie write to chip, potem na verify i potem na program chip. Żadnych błędów. Rezystor podciągający jest przylutowany jak na tym zdjęciu: http://img146.imageshack.us/i/pb260915.jpg/ Przesłałem również filmik z działaniem układu który znajduje się tu: http://www.youtube.com/watch?v=C_d9RpmxUak Możliwe że to wszystko się dzieje przez to że zastosowałem kondensatory 27pF zamiast 33pF? Myślałem że mają one wpływ na "miganie" wyświetlacza aczkolwiek nie mam teraz pewności.

Portret użytkownika mirley

Re: Termostat

Klikasz Compile a potem Program Chip, program chip załatwia erse + write + verify jak dobrze pamiętam, Jak klikałeś erse, write a potem verify to też dobrze. Rezystor podciągający jest dobrze bo jakby go nie było to czujnik temperatury nie działał by w ogóle. Na filmiku wiadać że wszystko działa tak jak powinno. Po kliknięciu przycisku wyświetlacz powinien migać co symbolizuje ustawienia. Kondensatory 33pF na 27pF nic nie zmienią. To że pojawi się czasami 79 stopni może być spowodowane zakłóceniami, np od dotykania nóżek ds'a podczas pomiaru itp.

Czemu natomiast podczas ustawiania miało by się raz zwiekszać raz zmniejszać wskazanie to nie mam pojęcia (podczas klikania tego samego przycisku). Martwi mnie jeszcze wyświetlanie.... zauważyłem cyfrę "9" bez kreski na dole, takiego znaku nie ma prawa być.... popatrz jeszcze czy wyświetlacz dobrze działa, czy jak wyjmiesz procka i zwierasz piny to wszystkie segmenty dobrze pracują

-

UWAGA! Możliwy jest zakup zaprogramowanych uC i zestawów elementów itp. do niektórych projektów. O dostępność proszę pytać via email. Konkretne oferty pojawiają się w cenniku.

Portret użytkownika ziko234

Termostat

temperaturę może i dobrze wyświetla chociaż trochę wydaje mi się zawyżona. Regulować się nic nie da bo jak klikam tym switchem bliżej kwarcu to jest tak: pojawia się watrość 30.0, po kliknięciu jest 30,7 potem 30,2; 30,3; 30,i te 9 bez kreski, potem 30,9; 30,8; 30,7; 30,8; 30,9 i od razu 37,0. Sytuacja się cały czas powtarza po włączeniu. ( tak wgl to co się nim reguluje?) zaś drugi switch bliżej czujnika po kliknięciu pojawia się wartość 2.0 potem 7,9; 7,8; 7,7; 7,8; 7,9; 7, ta dziwna dziewiątka, 7,3; 7,2; 7,7; 7.0; 0,9 i też takimi dziwnymi kombinacjami maleje do 0. Wyświetlacz był sprawdzany i przy zwarciu pinów 2,3 i 6 zapalały się górne połówki cyfr.

Portret użytkownika mirley

Re: Termostat

Sprawdź jeszcze raz podłączenie wywietlacza bo wydaje mi się że pomyliłeś piny. Program ne ma prawa zapalic takiej dziwnej dziewiatki, szczególnie że w innych kombinacjach zapala segment dolny.

piny na schemacie masz podpisane:

a P1.0 - górny poziomy
b P1.1 - górny prawy pionowy
c P1.2 - dolny prawy pionowy
d p1.3 - poziomy dolny
e p1.4 - dolny lewy pionowy
f p1.5 - górny lewy pionowy
g p1.6 - srodkowy poziomy
dp p1.7 - kropka dziesiętna

Zewrzyj najpierw P3.0 do masy i po kolei wszytkie piny z portu P1, czy zapala się tak jak opisałem, potem zwierasz P3.1 i znowu cały P1, na końcu to samo z P3.2. Jak wszystkie segmenty we wszystkich wyświetlaczach dobrze się zaświecą to dopiero zajmuj się innymi rzeczami

Termostat ma dwa ustawienia, jedno ustawia temperaturę progowa a drugie histerezę

Wartości początkowe temperatury ustawionej i histerezy da się przestawić na początku programu:

Tempu = 300     'wartośc w stopniach *10
Histereza = 20    'wartośc w stopniach *10

-

UWAGA! Możliwy jest zakup zaprogramowanych uC i zestawów elementów itp. do niektórych projektów. O dostępność proszę pytać via email. Konkretne oferty pojawiają się w cenniku.

Portret użytkownika gość

Cześć, masz może zrobioną

Cześć, masz może zrobioną płytkę ale pod atmege8, albo udostępnił byś plik z płytką aby można było go edytować?

Portret użytkownika mirley

Re: Płytka

Niestety nie dam rady przerobić tej płytki z powodu braku czasu, a zgodnie z zasadami które przyjąłem wcześniej na stronie umieszczam tylko pliki PDF.

-

UWAGA! Możliwy jest zakup zaprogramowanych uC i zestawów elementów itp. do niektórych projektów. O dostępność proszę pytać via email. Konkretne oferty pojawiają się w cenniku.

Portret użytkownika Norbis15

Czy potrzebny jest rezonator kwarcowy?

Witam. Mam pytanie jak w temacie, czy potrzebny jest rezonator kwarcowy do tego projektu? Czy można go nie lutować, a urzyć wewnętrznego oscylatora uC?

Portret użytkownika mirley

Re: Kwarc

Można uzyć wewnętrznego przy procesorze tiny2313, trzeba zmienic program żeby przerwanie bylo wykonywane równie czesto co dla modelowego układu i zmienic czestotliwośc na początku w deklaracji.

-

UWAGA! Możliwy jest zakup zaprogramowanych uC i zestawów elementów itp. do niektórych projektów. O dostępność proszę pytać via email. Konkretne oferty pojawiają się w cenniku.

Portret użytkownika gosc 95

Schemat.

Witam !!
Czy mogłby mi ktoś pomóc przerobić schemat na atmege8 ??

Portret użytkownika mirley

Re; M8

Ale tu nie ma żadnej filozofii, podłącz wyświetlacz na jeden cały port (np portB), jego anody do kilku pinów innego portu, tak żeby sie łatwo podłączyło na płytce, czujnik może być na dowolnym pinie, podobnie jak przyciski. Obwody zasilania mogą zostać takie jak na schemacie, kwarc może być ale nie musi byc bo i tak trzeba przerobic program więc na wewnetrznym 8MHz da radę działać.

-

UWAGA! Możliwy jest zakup zaprogramowanych uC i zestawów elementów itp. do niektórych projektów. O dostępność proszę pytać via email. Konkretne oferty pojawiają się w cenniku.

Portret użytkownika gosc 95

Numerowanie

A jak jest z tymi numerkami na schemacie? Bo nie mogeię doczytać ... Te co są w górnej części procesora ( rezystory ) to jakie one mają numerki ?

Portret użytkownika mirley

Re: Rezystory

Rezystory do ograniczenia prądu segmentów (od lewej) od R9 do R16, wszystkie 330R

-

UWAGA! Możliwy jest zakup zaprogramowanych uC i zestawów elementów itp. do niektórych projektów. O dostępność proszę pytać via email. Konkretne oferty pojawiają się w cenniku.

Portret użytkownika gosc 95

A do których numerków

A do których numerków procesora są one podłączone , bo jakoś dziwnie troche na schemacie jest.

Portret użytkownika mirley

Re: Termometr

od pinów 12 do 19..... karty katalogowej to się już nie da otworzyć na drugiej stronie? schemat jest troche kiepski ale bez przesady

-

UWAGA! Możliwy jest zakup zaprogramowanych uC i zestawów elementów itp. do niektórych projektów. O dostępność proszę pytać via email. Konkretne oferty pojawiają się w cenniku.

Portret użytkownika danioo

Cześć. Czy zamiast 2051 da

Cześć.
Czy zamiast 2051 da sie włozyć attiny 2313 bez przeróbek płytki oprucz tego co napisałeś wcześniej (kondenstatory) ??

jak ustawić fus'y dla attiny ??

Portret użytkownika mirley

Re; Termometr

Wszystko jet wyżej napisane... da się załozyć...program jest w załączniku a fusebity w rozdziale "programowanie"

-

UWAGA! Możliwy jest zakup zaprogramowanych uC i zestawów elementów itp. do niektórych projektów. O dostępność proszę pytać via email. Konkretne oferty pojawiają się w cenniku.

Portret użytkownika gość

Cześć gdzie zmienić w

Cześć gdzie zmienić w programie dla atmegi żeby sterować anodami ale z innych portów atmegi8

Portret użytkownika gosc 95

Witam ! To znowu ja ... Czy

Witam !
To znowu ja ... Czy " odpalenie " tego układu wiąże się z jakimiś konfiguracjami i ustawieniami " wnętrzności " procesora ? Bez żadnych ustawień itp. zadziała to ? Czy tak jak wcześniej wspomniałem trzeba cos ustawiac itp . ?

Portret użytkownika gość1234

Co trzeba zmienić w programie

Co trzeba zmienić w programie pod atmege8 aby działał na wewnętrznym oscylatorze 8MHz?

Portret użytkownika tomak

a jakim napięciem jest

a jakim napięciem jest zasilany termometr

Portret użytkownika gosc 95

Zależy gdzie... Czy sam

Zależy gdzie... Czy sam termometr , czy termometr zawarty w powyższym schemacie ?? Sam termometr , jak oczujnik jest zasilany napięciem : od 3v do 5.5v . A w powyższym schemacie to pewnie takim napięciem jakim zasilany jest procek , czyli gdzies w okolicach 5 v.

Portret użytkownika mirley

Re: Termometr

W procedurze wyświetl przypisujesz zmienne wysw na port, tak samo jak sterujesz anodami w poszczególnych cas'ach (te polecenia set i reset, reset włącza anodę, a set wyłącza poprzednią)

-------

Trzeba ustawić fusebity na zewnętrzny kwarc.... masz napisane ustawienia w artykule o fusebitach (patrz artykuły różne)

----

Zmienic fusebity, patrz wyżej..... w programie zadeklarowac 8MHz i timer zmienić tak aby przerwanie dalej było co założony czas

-

UWAGA! Możliwy jest zakup zaprogramowanych uC i zestawów elementów itp. do niektórych projektów. O dostępność proszę pytać via email. Konkretne oferty pojawiają się w cenniku.

Portret użytkownika gość1234

Quote:timer zmienić tak aby

Quote:
timer zmienić tak aby przerwanie dalej było co założony czas

A mógłbyś mi powiedzieć gdzie dokładnie zmienić w programie i na jakie wartości bo nie bardzo wiem o co chodzi z tym timerem.

Portret użytkownika gosc 95

Poczytaj sobie gdzieś w

Poczytaj sobie gdzieś w inetrnecie lub jakieś książce jak masz , o tym "całym timerze '.
Teraz mam pytanie do twórcy tego schematu. To pytanie jest odnośnie magistrali 1wire. Środkowa nóżka czujnika DQ powinna zostać podłączona do tej magistrali 1wire. Otóż mam płytkę ZL2AVR i tam jest właśnie ten jeden jedyny kołek podpisany " 1wire " . I czy właśnie ten kołek powinienem podłączyć na srodkową nóżkę czujnika ?
Wyczytałem w polskiej ppmocy do BASCOMA , że istnieje coś takiego jak 2wire (z wykorzystaniem 3 przewodów i 1Wire z wykorzystaniem 2przewodów) , którego w takim razie mam uzyc ? Bo tutaj rochodzi się o końcówkę zasilania .

Portret użytkownika tomak

jakie '' przeróbki należałoby

jakie '' przeróbki należałoby zrobić gdybym chciał umieścić tutaj mikrokontroler attiny 2313

Portret użytkownika gosc 95

Zazdroszę autorowi , że ma

Zazdroszę autorowi , że ma tyle cierpliwości .... Czy ty w ogóle czytałeś ten opis pod schematem ?!!!!! Zanim zadasz pytanie , zastanów się czy samemu nie znajdziesz na nie odpowiedzi....

Portret użytkownika mirley

Re: 1Wire/timer

Popatrz na schemat swojej płytki testowej... masz tam złącze ARK 1-wire i jeden pin 1-wire.... ten pojedynczy pin ma byc podłaczony do jakiegoś pinu procka za pomocą kabelka a czujnik do ARK... Możesz podłączyć 3 kable do czujnika i ja zawsze tak robie bo pewniej działa albo bez zasilania i wtedy konwersja trwa dłużej

-------

co do timera to na początku

Config Timer0 = Timer , Prescale = 256

a w obsłudze:

Przerwanie0:
Timer0 = 131
Incr Co4ms
 If Co4ms = 1 Then
   Co4ms = 0
...

Tak wogóle to tego ostatniego ifa trzeba by byłu usunąć bo nie jest juz potrzebny i zmienna co4ms tez nie jest potrzebna

-

UWAGA! Możliwy jest zakup zaprogramowanych uC i zestawów elementów itp. do niektórych projektów. O dostępność proszę pytać via email. Konkretne oferty pojawiają się w cenniku.

Portret użytkownika gosc 95

Witam ! Dziękuję za

Witam !
Dziękuję za odpowiedź.

Portret użytkownika gość

Dał byś rade przerobić

Dał byś rade przerobić program tak aby można było zapisywać na karcie sd lub w pamięci atmegi temperaturę co jakiś czas a później żeby można było sobie przenieś dane do komputera?

Portret użytkownika mirley

Re: SD

Przerobić program? raczej napisać od nowa a nie przerobić. Nie mam kiedy tego uczynić... musisz szukać gotowych rozwiązań w internecie

-

UWAGA! Możliwy jest zakup zaprogramowanych uC i zestawów elementów itp. do niektórych projektów. O dostępność proszę pytać via email. Konkretne oferty pojawiają się w cenniku.