Mirley - Elektronika i Programowanie

'****************************
           'Konfiguracja
'****************************
$crystal = 12000000                                           '12MHz
$regfile = "89C2051.DAT"
 
Config Timer0 = Timer , Gate = Internal , Mode = 2
On Timer0 Przerwanie0
Load Timer0 , 250
Enable Timer0
Start Timer0
 
Enable Interrupts
'****************************
       'Zmienne
'****************************
Dim Licznik As Byte
Dim Licznik2 As Byte
Dim Licznik_sygnal As Byte
Dim N As Byte
Dim Flaga As Bit
Dim Flaga2 As Bit
Dim Licz_sw(5) As Byte
Dim Ruch As Byte          '0=stop 1= gora 2=dol 3=gora max 4=dol max
Dim Kierunek As Bit
Dim Sstart As Bit
Dim Sygnal As Bit
Dim Sygnal_e As Bit
'****************************
      'Nazwy Wyprowadzeń
'****************************
Sw_down Alias P1.7
Sw_stop Alias P1.6
Sw_up Alias P1.5
 
Edge_max Alias P3.2
Edge_max_e Alias P3.3
Edge_min Alias P3.4
Edge_min_e Alias P3.5
 
P_start Alias P1.4
P_kierunek Alias P1.3
Buzzer Alias P1.2
 
'****************************
      'Wartosci Poczatkowe
'****************************
P1 = 255
P3 = 255
Set Flaga2
Reset Sygnal
 
Buzzer = 0
Waitms 100
Buzzer = 1
Waitms 100
Buzzer = 0
Waitms 100
Buzzer = 1
 
'****************************
      'Petla glowna
'****************************
Do
 
  If Sygnal_e = 1 Then
    For N = 1 To 10
      Buzzer = 0
      Waitms 100
      Buzzer = 1
      Waitms 100
    Next N
    Sygnal_e = 0
    Flaga2 = 1
  End If
 
 
  If Flaga = 1 And Flaga2 = 1 Then                            'co 10ms
    Reset Flaga
 
    If Sygnal = 1 Then
      Buzzer = 0
      Incr Licznik_sygnal
      If Licznik_sygnal = 20 Then
        Licznik_sygnal = 0
        Buzzer = 1
        Sygnal = 0
      End If
    End If
 
 
    If Sw_up = 0 And Sw_stop = 1 And Sw_down = 1 Then         'up
     Incr Licz_sw(1)
     If Licz_sw(1) = 255 Then
      Licz_sw(1) = 253
      Licznik2 = 0
      Ruch = 1
     End If
    Else
     Licz_sw(1) = 240
    End If
 
    If Sw_down = 0 And Sw_stop = 1 And Sw_up = 1then          'down
     Incr Licz_sw(2)
     If Licz_sw(2) = 255 Then
      Licz_sw(2) = 253
      Licznik2 = 0
      Ruch = 2
     End If
    Else
     Licz_sw(2) = 240
    End If
 
    If Sw_down = 1 And Sw_stop = 0 And Sw_up = 1 Then         'stop
     Incr Licz_sw(3)
     If Licz_sw(3) = 255 Then
      Licz_sw(3) = 253
      Ruch = 0
     End If
    Else
     Licz_sw(3) = 240
    End If
 
    If Sw_up = 0 And Sw_stop = 0 And Sw_down = 1 Then         'up max
     Incr Licz_sw(4)
     If Licz_sw(4) = 255 Then
      Licz_sw(4) = 253
      Ruch = 3
     End If
    Else
     Licz_sw(4) = 240
    End If
 
    If Sw_down = 0 And Sw_stop = 0 And Sw_up = 1 Then         'down max
     Incr Licz_sw(5)
     If Licz_sw(5) = 255 Then
      Licz_sw(5) = 253
      Ruch = 4
     End If
    Else
     Licz_sw(5) = 240
    End If
 
    Select Case Ruch
 
      Case 0:
        Kierunek = 1
        Sstart = 1
 
      Case 1:
        Kierunek = 1
        Sstart = 0
        Incr Licznik2
        If Licznik2 = 5 Then
          Licznik2 = 0
          Ruch = 0
        End If
        Gosub E_max
 
      Case 2:
        Kierunek = 0
        Sstart = 0
        Incr Licznik2
        If Licznik2 = 5 Then
          Licznik2 = 0
          Ruch = 0
        End If
        Gosub E_min
 
      Case 3:
        Kierunek = 1
        Sstart = 0
        Gosub E_max
 
      Case 4:
        Kierunek = 0
        Sstart = 0
        Gosub E_min
 
    End Select
 
  If P_kierunek <> Kierunek Then P_kierunek = Kierunek
  If P_start <> Sstart Then P_start = Sstart
 
  End If
Loop
End
'****************************
'Przerwanie timer0  co 250us
'****************************
Przerwanie0:
  Incr Licznik
  If Licznik = 40 Then
    Licznik = 0
    Set Flaga
  End If
Return
'****************************
      'Inne Etykiety
'****************************
E_max:
 If Edge_max = 0 Then
   Ruch = 0
   Kierunek = 1
   Sstart = 1
   Set Sygnal
 End If
 If Edge_max_e = 0 Then
   Ruch = 0
   Kierunek = 1
   Sstart = 1
   Flaga2 = 0
   Set Sygnal_e
 End If
Return
 
E_min:
 If Edge_min = 0 Then
   Ruch = 0
   Kierunek = 1
   Sstart = 1
   Set Sygnal
 End If
 If Edge_min_e = 0 Then
   Ruch = 0
   Kierunek = 1
   Sstart = 1
   Flaga2 = 0
   Set Sygnal_e
 End If
Return
'****************************